Function Reference

_GUICtrlTab_GetItemState

タブの状態を取得します。

#Include <GuiTab.au3>
_GUICtrlTab_GetItemState($hWnd, $iIndex)

 

パラメータ

$hWnd コントロールのハンドル
$iIndex ゼロ始まりのアイテムインデックス

 

返し値

成功: 次のタブ状態を表す整数:
        $TCIS_BUTTONPRESSED - タブコントロールアイテムが選択されています
        $TCIS_HIGHLIGHTED - タブコントロールアイテムがハイライトされています

 

注意

なし。

 

関連

_GUICtrlTab_SetItemState

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTab.au3>

Opt('MustDeclareVars', 1)

$Debug_TAB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hTab

    ; GUIを作成
    GUICreate("Tab Control Get Item State", 400, 300)
    $hTab = GUICtrlCreateTab(2, 2, 396, 296, $TCS_BUTTONS)
    GUISetState()

    ; タブを追加
    _GUICtrlTab_InsertItem($hTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($hTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($hTab, 2, "Tab 3")
   
    ; タブ2の状態を取得/設定
    _GUICtrlTab_SetItemState($hTab, 1, $TCIS_BUTTONPRESSED)
    MsgBox(4160, "Information", "Tab 2 state: " & _ExplainItemState(_GUICtrlTab_GetItemState($hTab, 1)))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Func _ExplainItemState($iState)
    Local $sText = ""
    If $iState = 0 Then $sText &= "No state set on this item" & @LF
    If BitAND($iState, $TCIS_BUTTONPRESSED) Then $sText &= "Button Pressed" & @LF
    If BitAND($iState, $TCIS_HIGHLIGHTED) Then $sText &= "Button Highlighted"
    Return $sText
EndFunc   ;==>_ExplainItemState