Function Reference

_GUICtrlToolbar_AddButton

ボタンを追加します。

#Include <GuiToolBar.au3>
_GUICtrlToolbar_AddButton($hWnd, $iID, $iImage[, $iString = 0[, $iStyle = 0[, $iState = 4[, $iParam = 0]]]])

 

パラメータ

$hWnd コントロールのハンドル
$iID コマンドID
$iImage ボタン画像のゼロ始まりのインデックス。
このパラメータを-1に設定するとコントロールは画像インデックスが必要な場合に$TBN_GETDISPINFO通知を送信して画像インデックスを取得します。
-2に設定するとボタンが画像を持たないことを意味し、ボタンの配置はテキスト用スペースのみ考慮しておこなわれます。
ボタンがセパレータの場合、このパラメータはピクセル単位でのセパレータの幅です。
$iString [オプション]AddStringで設定されたボタン文字列のゼロ始まりのインデックス
$iStyle [オプション]ボタンのスタイル。次のものの組み合わせです:
$BTNS_AUTOSIZE - ツールバーコントロールはボタンに標準の幅を割り当てません
$BTNS_BUTTON - 標準的なボタン
$BTNS_CHECK - 押した状態/押してない状態を切り替えます
$BTNS_CHECKGROUP - グループの他のボタンが押されるまで押された状態を維持するボタン
$BTNS_DROPDOWN - リストを表示できるドロップダウンスタイルのボタンを作成します
$BTNS_GROUP - グループの他のボタンが押されるまで押された状態を維持するボタン
$BTNS_NOPREFIX - ボタンテキストにアクセラレータの接頭辞を表示しません
$BTNS_SEP - セパレータを作成
$BTNS_SHOWTEXT - ボタンテキストが表示されるように指定します
$BTNS_WHOLEDROPDOWN - ボタンにドロップダウン用の矢印が表示されるように指定します
$iState [オプション]ボタンの状態。次のものの組み合わせです:
$TBSTATE_CHECKED - ボタンに$TBSTYLE_CHECKスタイルが設定され、クリックされた状態になります
$TBSTATE_PRESSED - ボタンがクリックされた状態になります
$TBSTATE_ENABLED - ボタンがユーザー入力を受け入れる様にします
$TBSTATE_HIDDEN - ボタンは非表示になり、ユーザー入力を受け入れません
$TBSTATE_INDETERMINATE - ボタンがグレイアウトします
$TBSTATE_WRAP - ボタンの後ろで改行します
$TBSTATE_ELLIPSES - ボタンテキストが切り捨てられ、省略記号が表示されます
$TBSTATE_MARKED - ボタンに印が付きます
$iParam [オプション]アプリケーション定義の値

 

返し値

成功: True
失敗: False

 

注意

なし。

 

関連

_GUICtrlToolbar_DeleteButton

 


#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hGUI, $hToolbar
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; GUIを作成
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create ($hGUI)
    GUISetState()

    ; 標準的なシステムのビットマップを追加
    _GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; ボタンを追加
    _GUICtrlToolbar_AddButton ($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton ($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton ($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep ($hToolbar)
    _GUICtrlToolbar_AddButton ($hToolbar, $idHelp, $STD_HELP)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main