Function Reference

_GUICtrlToolbar_Create

ツールバーコントロールを作成します。

#Include <GuiToolBar.au3>
_GUICtrlToolbar_Create($hWnd[, $iStyle = 0x00000800[, $iExStyle = 0x00000000]])

 

パラメータ

$hWnd 親ウィンドウまたはオーナーウィンドウのハンドル
$iStyle [オプション]コントロールのスタイル:
$BTNS_AUTOSIZE - コントロールが標準的な幅をボタンに設定しないよう指定します。
代わりにボタンのテキストと画像の幅に基づいてボタンの幅を計算します。
$BTNS_BUTTON - 標準的なボタンを作成します。
$BTNS_CHECK - ユーザーがクリックするたびに押した状態/押してない状態が切り替わる2状態を持つ押しボタンを作成します。
ボタンは押された状態の際に異なる背景色になります。
$BTNS_CHECKGROUP - オプションボタンのように同じグループの違うボタンが押されるまで押された状態が維持されるボタンを作成します。
$BTNS_CHECKと$BTNS_GROUPの組み合わせと同じです。
$BTNS_DROPDOWN - ボタンがクリックされた際にリストを表示するドロップダウンスタイルのボタンを作成します。
通常のボタンで使用される$WM_COMMANDメッセージの代わりに、ドロップダウンボタンは$TBN_DROPDOWNメッセージを送信します。
アプリケーションは オプションのリストを表示する通知ハンドラを持つことができます。
ツールバーに$TBSTYLE_EX_DRAWDDARROWS拡張スタイルが設定されている場合、ドロップダウンボタンの右側の別セクションにドロップダウン用矢印が表示され、
矢印がクリックされると$TBN_DROPDOWN通知が送信されます。
関連するボタンがクリックされると$WM_COMMANDが送信されます。
$BTNS_GROUP - $BTNS_CHECKと組み合わせると、同じグループの違うボタンが押されるまで押された状態が維持されるボタンを作成します。
$BTNS_NOPREFIX - ボタンテキストに関連するアクセラレータ接頭辞を付けないように指定します。
$BTNS_SEP - ボタングループ間に小さい隙間を空けるためのセパレータを作成します。
このスタイルが設定されたボタンはユーザー入力を受け付けません。
$BTNS_SHOWTEXT - ボタンテキストが表示されるように指定します。 全てのボタンにはテキストを設定することができますが、$BTNS_SHOWTEXTボタンスタイルを設定したボタンのみがそれを表示します。
このボタンスタイルは$TBSTYLE_LISTスタイルと$TBSTYLE_EX_MIXEDBUTTONS拡張スタイルとともに使用される必要があります。
$BTNS_SHOWTEXTスタイルの設定されていないボタンにテキストを設定した場合、
ツールバーコントロールはカーソルがボタン上に来た際に自動的にそのテキストをツールチップ上に表示します。
この機能によってアプリケーションでツールバー用に$TBN_GETINFOTIP メッセージを処理する必要がなくなります。
$BTNS_WHOLEDROPDOWN - ボタンにドロップダウン用の矢印を設定します。ただし場所は別セクションではありません。
このスタイルが設定されたボタンの動作は$TBSTYLE_EX_DRAWDDARROWS拡張スタイルが設定されているかどうかに関係なく同じです。
$TBSTYLE_ALTDRAG - ALTキーを押しながらドラッグすることでユーザーがツールバーのボタン位置を変更できるようにします。
このスタイルが指定されていない場合、ユーザーはボタンのドラッグ中にSHIFTキーを押すことになります。
ツールバーボタンのドラッグを有効にするには$CCS_ADJUSTABLEスタイルが指定されていなければならないことに注意してください。
$TBSTYLE_CUSTOMERASE - ツールバーが$WM_ERASEBKGNDメッセージを処理する際に$NM_CUSTOMDRAWメッセージを発生するようにします。
$TBSTYLE_FLAT - 平らなツールバーを作成します
$TBSTYLE_LIST - ビットマップの隣にボタンテキストを持つ平らなツールバーを作成します
$TBSTYLE_REGISTERDROP - カーソルがツールバーボタン上を通過した際にドロップターゲットオブジェクトを要求するための$TBN_GETOBJECT通知メッセージを 発生するようにします。
$TBSTYLE_TOOLTIPS - アプリケーションがツールバー内のボタンの説明テキストを表示するために使用できるツールチップコントロールを作成します。
$TBSTYLE_TRANSPARENT - 透明なツールバーを作成します。透明なツールバーではツールバーは透明ですがボタンは不透明です。
ボタンテキストはボタンビットマップの下に表示されます。
再描画の問題を防ぐにはこのスタイルをツールバーの表示前に設定しておく必要があります。
$TBSTYLE_WRAPABLE - 複数行のボタン配置をできるツールバーを作成します。
ツールバーが全てのボタンを1行で配置するには狭すぎるようになるとツールバーのボタンに対して次行への"丸め込み"がおこなわれます。
丸め込まれる際は最右端のセパレータ、バー上にセパレータがない場合は最右端のボタンで改行がおこなわれます。
ツールバーが垂直レバーコントロールの一部の場合、垂直ツールバーを表示する際にはこのスタイルを設定する必要があります。
デフォルト: $TBSTYLE_FLAT
強制 : $WS_CHILD、 $WS_CLIPSIBLINGS、 $WS_VISIBLE
$iExStyle [オプション]コントロールの拡張スタイル:
$TBSTYLE_EX_DRAWDDARROWS - ボタンが別にドロップダウン用矢印を持てるようにします。
$BTNS_DROPDOWNスタイルが設定されたボタンはボタン右側に別セクションのドロップダウン矢印と共に描画されます。
矢印がクリックされるとボタンの矢印部分のみが押し下げられ、ツールバーコントロールはアプリケーションがドロップダウンメニューを表示するように$TBN_DROPDOWN通知を送信します。
ボタンのメイン部分が押されるとツールバーコントロールは$WM_COMMANDメッセージをボタンのIDとともに送信します。
$TBSTYLE_EX_HIDECLIPPEDBUTTONS - 部分的にクリップボタンを非表示
$TBSTYLE_EX_DOUBLEBUFFER - ツールバーを二重にバッファします
$TBSTYLE_EX_MIXEDBUTTONS - 全てのボタンにテキスト設定できるようになり、$BTNS_SHOWTEXTボタンスタイル設定されているボタンでそれを表示できるようにします。 $TBSTYLE_LISTスタイルも設定する必要があります。
通常、ボタンがテキスト表示をおこなわない場合はツールチップに表示するために$TBN_GETINFOTIPを制御しなければなりません。
$TBSTYLE_EX_MIXEDBUTTONS拡張スタイルを設定することで ボタンに設定されているものの表示はされないテキストが自動的にボタンのツールチップテキストとして使用されます。
$TBN_GETINFOTIPを制御する必要があるのはツールチップテキストの指定をより柔軟におこなう必要がある場合だけです。

 

返し値

成功: ツールバーコントロールのハンドル
失敗: 0

 

注意

なし。

 

関連

_GUICtrlToolbar_Destroy

 


#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Global $hToolbar, $iMemo
Global $iItem ; 通知に関連付けられたボタンのコマンド識別子
Global Enum $idNew = 1000, $idOpen, $idSave, $idHelp

_Main()

Func _Main()
    Local $hGUI, $aSize

    ; GUIを作成
    $hGUI = GUICreate("Toolbar", 600, 400)
    $hToolbar = _GUICtrlToolbar_Create ($hGUI)
    $aSize = _GUICtrlToolbar_GetMaxSize ($hToolbar)

    $iMemo = GUICtrlCreateEdit("", 2, $aSize[1] + 20, 596, 396 - ($aSize[1] + 20), $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()
    GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

    ; 標準的なシステムのビットマップを追加
    _GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; ボタンを追加
    _GUICtrlToolbar_AddButton ($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton ($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton ($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep ($hToolbar)
    _GUICtrlToolbar_AddButton ($hToolbar, $idHelp, $STD_HELP)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; WM_NOTIFYイベントハンドラ
Func _WM_NOTIFY($hWndGUI, $MsgID, $wParam, $lParam)
    #forceref $hWndGUI, $MsgID, $wParam
    Local $tNMHDR, $event, $hwndFrom, $code, $i_idNew, $dwFlags, $lResult, $idFrom, $i_idOld
    Local $tNMTOOLBAR, $tNMTBHOTITEM
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hwndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $idFrom = DllStructGetData($tNMHDR, "IDFrom")
    $code = DllStructGetData($tNMHDR, "Code")
    Switch $hwndFrom
        Case $hToolbar
            Switch $code
                Case $NM_LDOWN
                    ;----------------------------------------------------------------------------------------------
                    MemoWrite("$NM_LDOWN: Clicked Item: " & $iItem & " at index: " & _GUICtrlToolbar_CommandToIndex ($hToolbar, $iItem))
                    ;----------------------------------------------------------------------------------------------
                Case $TBN_HOTITEMCHANGE
                    $tNMTBHOTITEM = DllStructCreate($tagNMTBHOTITEM, $lParam)
                    $i_idOld = DllStructGetData($tNMTBHOTITEM, "idOld")
                    $i_idNew = DllStructGetData($tNMTBHOTITEM, "idNew")
                    $iItem = $i_idNew
                    $dwFlags = DllStructGetData($tNMTBHOTITEM, "dwFlags")
                    If BitAND($dwFlags, $HICF_LEAVING) = $HICF_LEAVING Then
                        MemoWrite("$HICF_LEAVING: " & $i_idOld)
                    Else
                        Switch $i_idNew
                            Case $idNew
                                ;----------------------------------------------------------------------------------------------
                                MemoWrite("$TBN_HOTITEMCHANGE: $idNew")
                                ;----------------------------------------------------------------------------------------------
                            Case $idOpen
                                ;----------------------------------------------------------------------------------------------
                                MemoWrite("$TBN_HOTITEMCHANGE: $idOpen")
                                ;----------------------------------------------------------------------------------------------
                            Case $idSave
                                ;----------------------------------------------------------------------------------------------
                                MemoWrite("$TBN_HOTITEMCHANGE: $idSave")
                                ;----------------------------------------------------------------------------------------------
                            Case $idHelp
                                ;----------------------------------------------------------------------------------------------
                                MemoWrite("$TBN_HOTITEMCHANGE: $idHelp")
                                ;----------------------------------------------------------------------------------------------
                        EndSwitch
                    EndIf
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_NOTIFY