Function Reference

_GUICtrlToolbar_GetButtonBitmap

ボタンに関連付けられたビットマップのインデックスを取得します。

#Include <GuiToolBar.au3>
_GUICtrlToolbar_GetButtonBitmap($hWnd, $iCommandID)

 

パラメータ

$hWnd コントロールのハンドル
$iCommandID ボタンのコマンドID

 

返し値

成功: ボタン用ビットマップのゼロ始まりのインデックス

 

注意

なし。

 

関連

_GUICtrlToolbar_SetButtonBitmap

 


#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hGUI, $hToolbar
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; GUIを作成
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create ($hGUI)
    GUISetState()

    ; 標準的なシステムのビットマップを追加
    Switch _GUICtrlToolbar_GetBitmapFlags ($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; ボタンを追加
    _GUICtrlToolbar_AddButton ($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton ($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton ($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep ($hToolbar)
    _GUICtrlToolbar_AddButton ($hToolbar, $idHelp, $STD_HELP)

    ; セーブボタンのビットマップのインデックスを表示
    MsgBox(4096, "Information", "Changing Save bitmap to Print bitmap")
    _GUICtrlToolbar_SetButtonBitMap ($hToolbar, $idSave, $STD_PRINT)
    MsgBox(4096, "Information", "Save button bitmap index: " & _GUICtrlToolbar_GetButtonBitmap ($hToolbar, $idSave))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main