Function Reference

_GUICtrlToolbar_GetButtonInfoEx

ボタンの情報を取得します。

#Include <GuiToolBar.au3>
_GUICtrlToolbar_GetButtonInfoEx($hWnd, $iCommandID)

 

パラメータ

$hWnd コントロールのハンドル
$iCommandID ボタンのコマンドID

 

返し値

成功: $tagTBBUTTONINFO構造体

 

注意

なし。

 

関連

_GUICtrlToolbar_SetButtonInfoEx, $tagTBBUTTONINFO

 


#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $tButton
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; GUIを作成
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create ($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; 標準的なシステムのビットマップを追加
    Switch _GUICtrlToolbar_GetBitmapFlags ($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; ボタンを追加
    _GUICtrlToolbar_AddButton ($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton ($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton ($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep ($hToolbar)
    _GUICtrlToolbar_AddButton ($hToolbar, $idHelp, $STD_HELP)

    ; セーブボタンの情報を設定
    $tButton = DllStructCreate($tagTBBUTTONINFO)
    DllStructSetData($tButton, "Mask", BitOR($TBIF_IMAGE, $TBIF_STATE, $TBIF_SIZE, $TBIF_LPARAM))
    DllStructSetData($tButton, "State", BitOR($TBSTATE_PRESSED, $TBSTATE_ENABLED))
    DllStructSetData($tButton, "Image", $STD_PRINT)
    DllStructSetData($tButton, "CX", 100)
    DllStructSetData($tButton, "Param", 1234)
    _GUICtrlToolbar_SetButtonInfoEx ($hToolbar, $idSave, $tButton)

    ; セーブボタンの情報を表示
    $tButton = _GUICtrlToolbar_GetButtonInfoEx ($hToolbar, $idSave)
    MemoWrite("Image index ....: " & DllStructGetData($tButton, "Image"))
    MemoWrite("State flags ....: " & DllStructGetData($tButton, "State"))
    MemoWrite("Button width ...: " & DllStructGetData($tButton, "CX"))
    MemoWrite("Param ..........: " & DllStructGetData($tButton, "Param"))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite