Function Reference

_GUICtrlToolbar_SetButtonStyle

ボタンのスタイルフラグを設定します。

#Include <GuiToolBar.au3>
_GUICtrlToolbar_SetButtonStyle($hWnd, $iCommandID, $iStyle)

 

パラメータ

$hWnd コントロールのハンドル
$iCommandID ボタンのコマンドID
$iStyle ボタンのスタイル。次の1つまたは組み合わせです:
$BTNS_AUTOSIZE - ツールバーコントロールはボタンに標準の幅を割り当てません
$BTNS_CHECK - 押した状態/押してない状態を切り替えます
$BTNS_CHECKGROUP - グループの他のボタンが押されるまで押された状態を維持するボタン
$BTNS_DROPDOWN - リストを表示できるドロップダウンスタイルのボタン
$BTNS_GROUP - グループの他のボタンが押されるまで押された状態を維持するボタン
$BTNS_NOPREFIX - ボタンテキストにアクセラレータの接頭辞を表示しません
$BTNS_SEP - セパレータ
$BTNS_SHOWTEXT - ボタンテキストが表示されます
$BTNS_WHOLEDROPDOWN - ボタンにドロップダウン用の矢印が表示されます

 

返し値

成功: True
失敗: False

 

注意

なし。

 

関連

_GUICtrlToolbar_GetButtonStyle

 


#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; GUIを作成
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; 標準的なシステムのビットマップを追加
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; ボタンを追加
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; セーブボタンのスタイルを設定
    _GUICtrlToolbar_SetButtonStyle($hToolbar, $idSave, $BTNS_CHECK)

    ; セーブボタンのスタイルを表示
    MemoWrite("Save button style: " & _GUICtrlToolbar_GetButtonStyle($hToolbar, $idSave))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite