Function Reference

_GUICtrlToolbar_SetButtonWidth

ツールバーコントロールでのボタンの最小・最大幅を設定します。

#Include <GuiToolBar.au3>
_GUICtrlToolbar_SetButtonWidth($hWnd, $iMin, $iMax)

 

パラメータ

$hWnd コントロールのハンドル
$iMin ピクセル単位での最小ボタン幅
$iMax ピクセル単位での最大ボタン幅

 

返し値

成功: True
失敗: False

 

注意

なし。

 

関連

 


#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aStrings[4]
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; GUIを作成
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState()

    ; ボタンラベルの複数行設定を有効にする
    _GUICtrlToolbar_SetButtonWidth($hToolbar, 32, 40)
    _GUICtrlToolbar_SetMaxTextRows($hToolbar, 2)

    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; 文字列を追加
    $aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&New Button")
    $aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Open Button")
    $aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Save Button")
    $aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Help Button")

    ; ボタンを追加
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW, $aStrings[0])
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN, $aStrings[1])
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE, $aStrings[2])
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])

    ; テキスト行数を表示
    MsgBox(4096, "Information", "Number of text rows:" & _GUICtrlToolbar_GetTextRows($hToolbar))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main