Function Reference

_GUICtrlToolbar_SetExtendedStyle

コントロールの拡張スタイルを設定します。

#Include <GuiToolBar.au3>
_GUICtrlToolbar_SetExtendedStyle($hWnd, $iStyle)

 

パラメータ

$hWnd コントロールのハンドル
$iStyle コントロールの拡張スタイル。次の1つまたは組み合わせです:
$TBSTYLE_EX_DRAWDDARROWS - ボタンが別にドロップダウン用矢印を持てるようにします
$TBSTYLE_EX_MIXEDBUTTONS - テキストと画像のミキシングボタンにします
$TBSTYLE_EX_HIDECLIPPEDBUTTONS - 部分的にクリップボタンを非表示
$TBSTYLE_EX_DOUBLEBUFFER - ツールバーを二重にバッファします

 

返し値

成功: 以前の拡張スタイル

 

注意

なし。

 

関連

_GUICtrlToolbar_GetExtendedStyle

 


#include <GuiToolbar.au3>
#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_TB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $hGUI, $iMemo

_Main()

Func _Main()
    Local $hToolbar
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; GUIを作成
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    _GUICtrlToolbar_SetExtendedStyle($hToolbar, $TBSTYLE_EX_DRAWDDARROWS)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; 標準的なシステムのビットマップを追加
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; ボタンを追加
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW, 0, $BTNS_DROPDOWN)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; 使用されている拡張スタイルを表示
    MemoWrite("Extended sytles: " & _GUICtrlToolbar_GetExtendedStyle($hToolbar))

    ; ユーザーが終了するまでループ
    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; TBN_DROPDOWNメッセージを制御
Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $tNMHDR, $iCode, $hMenu

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $iCode = DllStructGetData($tNMHDR, "Code")

    If $iCode = $TBN_DROPDOWN Then
        $hMenu = _GUICtrlMenu_CreatePopup()
        _GUICtrlMenu_AddMenuItem($hMenu, "Template 1", 2000)
        _GUICtrlMenu_AddMenuItem($hMenu, "Template 2", 2001)
        _GUICtrlMenu_AddMenuItem($hMenu, "Template 3", 2002)
        _GUICtrlMenu_TrackPopupMenu($hMenu, $hGUI)
        _GUICtrlMenu_DestroyMenu($hMenu)
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY