新しいアイテムを追加します。
#Include <GuiTreeView.au3>
_GUICtrlTreeView_AddFirst($hWnd, $hSibling, $sText[, $iImage = -1[, $iSelImage = -1]])
パラメータ
| $hWnd | コントロールのハンドル |
| $hSibling | 同じレベルのアイテム |
| $sText | アイテムのテキスト |
| $iImage | [オプション]コントロールの画像リスト内のアイテムアイコンのゼロ始まりのインデックス |
| $iSelImage | [オプション]コントロールの画像リスト内のアイテムアイコンのゼロ始まりのインデックス |
返し値
| 成功: | 新しいアイテムのハンドル |
| 失敗: | 0 |
注意
アイテムは$hSiblingの1番目の兄弟アイテムとして追加され、追加アイテムの後ろのアイテムは下に移動します。
関連
_GUICtrlTreeView_Add
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_TV = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $hItem, $hTreeView
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
GUICreate("TreeView Add First", 400, 300)
$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState()
_GUICtrlTreeView_BeginUpdate($hTreeView)
For $x = 1 To Random(2, 10, 1)
$hItem = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x))
For $y = 1 To Random(2, 10, 1)
_GUICtrlTreeView_AddChild($hTreeView, $hItem, StringFormat("[%02d] New Child", $y))
Next
Next
_GUICtrlTreeView_AddFirst($hTreeView, $hItem, "[00] New First Item")
_GUICtrlTreeView_EndUpdate($hTreeView)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main