Function Reference

_GUICtrlTreeView_GetISearchString

インクリメンタル検索文字列を取得します。

#Include <GuiTreeView.au3>
_GUICtrlTreeView_GetISearchString($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: コントロールがインクリメンタル検索モードの場合はインクリメンタル検索文字列。
失敗: ""

 

注意

インクリメンタル検索文字列はユーザーによって入力された文字に基づいてアイテムを選択する際に使用されます。

 

関連

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_TV = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()

    Local $hItem[6], $hImage, $hTreeView
    Local $sText[6] = ["AutoIt", "freeware", "BASIC-like", "scripting", "language", "automating"]
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
   
    GUICreate("TreeView Get ISearch String", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
        $hItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, $sText[$x], $x, $x)
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    Send($sText[Random(0, 5, 1)])
    MsgBox(4160, "Information", "ISearch String: " & _GUICtrlTreeView_GetISearchString($hTreeView))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main