Function Reference

_GUICtrlTreeView_GetScrollTime

最大スクロール時間を取得します。

#Include <GuiTreeView.au3>
_GUICtrlTreeView_GetScrollTime($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

ミリ秒単位での最大スクロール時間を返します。

 

注意

最大スクロール時間とはスクロール操作にかかる最大時間のことです。
スクロールは最大スクロール時間内に完了するように調整されます。
スクロール操作は最大時間内に完了します。

 

関連

_GUICtrlTreeView_SetScrollTime

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_TV = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()

    Local $hItem[10], $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
   
    GUICreate("TreeView Get Scroll Time", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 9
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $hTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $hItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)
   
    _GUICtrlTreeView_SetScrollTime($hTreeView, 2)
    MsgBox(4160, "Information", "Scroll Time: " & _GUICtrlTreeView_GetScrollTime($hTreeView) & " milliseconds")

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main