イメージリストコントロールを作成します。
#Include <GuiImageList.au3>
_GUIImageList_Create([$iCX=16[, $iCY=16[, $iColor=4[, $iOptions=0[, $iInitial=4[, $iGrow=4]]]]]])
パラメータ
| $iCX | [オプション]各画像のピクセル単位での幅 |
| $iCY | [オプション]各画像のピクセル単位での高さ |
| $iColor | [オプション]画像の色深度: 0 - デフォルト設定を使用します 1 - 4ビットのDIBセクションを使用します 2 - 8ビットのDIBセクションを使用します 3 - 16ビットのDIBセクションを使用します 4 - 24ビットのDIBセクションを使用します 5 - 32ビットのDIBセクションを使用します 6 - デバイス依存のビットマップを使用します |
| $iOptions | [オプション]オプションフラグ。次のものの組み合わせです: 1 - マスクを使用します 2 - リスト内の画像をミラーします 4 - イメージリストに画像のストリップを格納します |
| $iInitial | [オプション]イメージリスト内の画像の初期数 |
| $iGrow | [オプション]システムが新しい画像のための領域作成を必要とした際にイメージリストが増やせる画像の数。 このパラメータはサイズ変更されたイメージリストが格納できる新しい画像の数を表します。 |
返し値
| 成功: | 新しいコントロールのハンドル |
| 失敗: | 0 |
注意
なし。
関連
_GUIImageList_Destroy
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <WinAPI.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $listview, $hImage
Local $exStyles = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)
GUICreate("ImageList Create", 400, 300)
$listview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
_GUICtrlListView_SetExtendedListViewStyle($listview, $exStyles)
GUISetState()
; 画像をロード
$hImage = _GUIImageList_Create(11, 11)
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($listview), 0xFF0000, 11, 11))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($listview), 0x00FF00, 11, 11))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($listview), 0x0000FF, 11, 11))
_GUICtrlListView_SetImageList($listview, $hImage, 1)
; 列を追加
_GUICtrlListView_AddColumn($listview, "Items", 120)
; アイテムを追加
_GUICtrlListView_AddItem($listview, "Item 1", 0)
_GUICtrlListView_AddItem($listview, "Item 2", 1)
_GUICtrlListView_AddItem($listview, "Item 3", 2)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main