ドキュメント全体のHTMLを置き換えます。
#include <IE.au3>
_IEDocWriteHTML ( ByRef $o_object, $s_html )
パラメータ
| $o_object | InternetExplorer.Applicationのオブジェクト変数、ウィンドウまたはフレームオブジェクト |
| $s_html | ドキュメントに書き込むHTML文字列 |
返し値
| 成功: | -1を返します |
| 失敗: | 0を返し@ERRORを設定します |
| @Error: | 0 ($_IEStatus_Success) = 正常終了 |
| 1 ($_IEStatus_GeneralError) = 一般的なエラー | |
| 3 ($_IEStatus_InvalidDataType) = 無効なデータ型 | |
| 4 ($_IEStatus_InvalidObjectType) = 無効なオブジェクト型 | |
| 6 ($_IEStatus_LoadWaitTimeout) = ロード待機タイムアウト | |
| 8 ($_IEStatus_AccessIsDenied) = アクセス拒否 | |
| 9 ($_IEStatus_ClientDisconnected) = クライアント切断 | |
| @Extended: | 無効なパラメータの番号が格納されています |
注意
この関数はブラウザまたはフレームのドキュメントの内容を完全に置き換えます。カスタムしたHTML、JavaScriptで新しいページを作成する場合に使用できます。
関連
_IEDocReadHTML, _IELoadWait
例
; *******************************************************
; 例 1 - 空のブラウザを作成し、カスタムしたHTMLを書き込む。
; 今回はFRAMESET。その後、各フレームの内容を更新
; *******************************************************
;
#include <IE.au3>
$oIE = _IECreate ()
$sHTML = ""
$sHTML &= "<HTML>" & @CR
$sHTML &= "<HEAD>" & @CR
$sHTML &= "<TITLE>_IE_Example('frameset')</TITLE>" & @CR
$sHTML &= "</HEAD>" & @CR
$sHTML &= "<FRAMESET rows='25,200'>" & @CR
$sHTML &= " <FRAME NAME=Top SRC=about:blank>" & @CR
$sHTML &= " <FRAMESET cols='100,500'>" & @CR
$sHTML &= " <FRAME NAME=Menu SRC=about:blank>" & @CR
$sHTML &= " <FRAME NAME=Main SRC=about:blank>" & @CR
$sHTML &= " </FRAMESET>" & @CR
$sHTML &= "</FRAMESET>" & @CR
$sHTML &= "</HTML>"
_IEDocWriteHTML ($oIE, $sHTML)
_IEAction ($oIE, "refresh")
Local $oFrameTop = _IEFrameGetObjByName ($oIE, "Top")
Local $oFrameMenu = _IEFrameGetObjByName ($oIE, "Menu")
Local $oFrameMain = _IEFrameGetObjByName ($oIE, "Main")
_IEBodyWriteHTML ($oFrameTop, '$oFrameTop = _IEFrameGetObjByName($oIE, "Top")')
_IEBodyWriteHTML ($oFrameMenu, '$oFrameMenu = _IEFrameGetObjByName($oIE, "Menu")')
_IEBodyWriteHTML ($oFrameMain, '$oFrameMain = _IEFrameGetObjByName($oIE, "Main")')