Function Reference

_Net_Share_SessionEnum

サーバー上で確立されているセッションの情報を提供します。

#Include <NetShare.au3>
_Net_Share_SessionEnum([$sServer = ""[, $sClientName = ""[, $sUserName = ""]]])

 

パラメータ

$sServer [オプション]この関数が実行されるリモートサーバーのDNSまたはNetBIOS名を指定する文字列。
このパラメータが空白の場合、ローカルコンピュータが使用されます。
$sClientName [オプション]情報を返すコンピュータセッションの名前を指定します。
このパラメータが空白の場合、この関数はサーバー上の全てのコンピュータセッションの情報を返します。
$sUserName [オプション]情報を返すユーザーの名前を返します。
このパラメータが空白の場合、この関数は全てのユーザーの情報を返します。

 

返し値

成功: 次のフォーマットの配列:
[0][0] - 配列内のエントリー数
[1][0] - セッションが確立されているコンピュータの名前
[1][1] - セッションを確立したユーザーの名前
[1][2] - セッション中に開かれたファイル、デバイス、パイプの数
[1][3] - セッションがアクティブになっていた秒数
[1][4] - セッションがアイドリングしていた秒数
[1][5] - ユーザーがどのようにセッションを確立したかを指定します:
1 - ゲストアカウントを使ってセッションを確立
2 - パスワードの暗号化を使用せずにセッションを確立
[1][6] - セッションを確立したクライアントの種類を指定します
[1][7] - クライアントを使用しているトランスポート名
失敗: @errorを設定します

 

注意

管理者グループ、サーバーオペレータローカルグループのメンバーのみこの関数を実行できます

 

関連

_Net_Share_ConnectionEnum, _Net_Share_FileEnum, _Net_Share_ShareEnum

 

こちらも参照

MSDNライブラリでNetSessionEnumを検索して下さい。

 


#include <GuiConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $sServer, $aInfo

    ; GUI作成
    $hGUI = GUICreate("NetShare", 400, 300)

    ; メモコントロール作成
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; サーバー情報、共有情報の取得
    $sServer = InputBox("NetWork Demo", "Enter Server Name:", "\\MyServer", "", 200, 130)
    If @error Then Exit

    ; ネットワークセッションを列挙
    $aInfo = _Net_Share_SessionEnum ($sServer, @ComputerName)
    MemoWrite("Error ..........: " & @error)
    MemoWrite("Entries read ...: " & $aInfo[0][0])
    For $iI = 1 To $aInfo[0][0]
        MemoWrite("Computer name ..: " & $aInfo[$iI][0])
        MemoWrite("User name.......: " & $aInfo[$iI][1])
        MemoWrite("Resources open .: " & $aInfo[$iI][2])
        MemoWrite("Seconds active .: " & $aInfo[$iI][3])
        MemoWrite("Seconds idle ...: " & $aInfo[$iI][4])
        MemoWrite("Connection type : " & $aInfo[$iI][5])
        MemoWrite("Client type ....: " & $aInfo[$iI][6])
        MemoWrite("Transport ......: " & $aInfo[$iI][7])
        MemoWrite()
    Next

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; メモにメッセージ書き込み
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite