Function Reference

_Net_Share_ShareGetInfo

サーバー上の特定の共有リソースの情報を取得します。

#Include <NetShare.au3>
_Net_Share_ShareGetInfo($sServer, $sShare)

 

パラメータ

$sServer この関数が実行されるリモートサーバーのDNSまたはNetBIOS名を指定する文字列。
このパラメータが空白の場合、ローカルコンピュータが使用されます。
$sShare 情報が返されるリソースの名前

 

返し値

成功: 次のフォーマットの配列:
[0] - リソースの共有名
[1] - 共有ソースの種類。次のものの組み合わせ:
$STYPE_DISKTREE - プリントキュー
$STYPE_PRINTQ - ディスクドライブ
$STYPE_DEVICE - 通信機器
$STYPE_IPC - IPC
$STYPE_SPECIAL - IPC$用またはサーバーのリモート管理用の特別な共有
$STYPE_TEMPORARY - 一時的な共有
[2] - 共有リソースのオプションコメント
[3] - 共有リソースのアクセス許可を表します:
1 - リソースからのデータ読み込みと実行を許可
2 - リソースへのデータ書き込み許可
4 - リソースのインスタンス作成許可
8 - リソースの実行許可
16 - リソースの削除許可
32 - リソースの属性変更許可
64 - リソースのアクセス権限変更許可
[4] - リソースの保持できる接続の最大数を表します
[5] - 現在のリソースへの接続数を表します
[6] - 共有リソースのローカルパスを指定します
[7] - 共有のパスワードを指定します
失敗: @errorを設定します

 

注意

管理者、サーバーオペレータ、パワーユーザーローカルグループまたはプリント、サーバーオペレータグループメンバー権限を持っている者のみこの関数を実行できます。

 

関連

_Net_Share_FileGetInfo, _Net_Share_SessionGetInfo, _Net_Share_ShareSetInfo

 

こちらも参照

MSDNライブラリでNetShareGetInfoを検索して下さい。

 


#include <GuiConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $iI, $aInfo
    Local Const $sShareName = "AutoIt Share"

    ; GUI作成
    $hGUI = GUICreate("NetShare", 400, 300)

    ; メモコントロール作成
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 共有が存在するか確認
    If _Net_Share_ShareCheck (@ComputerName, $sShareName) = -1 Then
        ; ローカルコンピュータ上に共有を作成
        _Net_Share_ShareAdd (@ComputerName, $sShareName, 0, "C:\", "AutoIt Share Comment")
        If @error Then MsgBox(4096, "Information", "Share add error : " & @error)
        MemoWrite("Share added")
    Else
        MemoWrite("Share exists")
    EndIf

    ; 追加した共有の情報を表示
    $aInfo = _Net_Share_ShareGetInfo (@ComputerName, $sShareName)
    MemoWrite("Share name ..............: " & $aInfo[0])
    MemoWrite("Share type...............: " & _Net_Share_ResourceStr ($aInfo[1]))
    MemoWrite("Comment .................: " & $aInfo[2])
    MemoWrite("Permissions .............: " & _Net_Share_PermStr ($aInfo[3]))
    MemoWrite("Maximum connections .....: " & $aInfo[4])
    MemoWrite("Current connections .....: " & $aInfo[5])
    MemoWrite("Local path ..............: " & $aInfo[6])
    MemoWrite("Password ................: " & $aInfo[7])

    ; 共有を削除
    _Net_Share_ShareDel (@ComputerName, $sShareName)
    If @error Then MsgBox(4096, "Information", "Share delete error : " & @error)
    MemoWrite("Share deleted")

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; メモにメッセージ書き込み
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite