Function Reference

_SQLite_QueryReset

_SQLite_Query()に基づくクエリをリセットします。

#include <SQLite.au3>
_SQLite_QueryReset ( $hQuery )

 

パラメータ

$hQuery _SQLite_Query()から渡されるクエリハンドル

 

返し値

成功: $SQLITE_OKを返します
失敗: $SQLITE_* 定数と比較可能な値を返します
@error: -1 - SQLiteがエラーを報告 (返し値を調べてください)
1 - SQLite API 'sqlite3_reset'の呼び出しエラー
2 - SafeModeによって呼び出しが阻止されました

 

注意

同じクエリを異なったパラメータで再実行したい場合、sqlite3_finalize()の代わりにsqlite3_reset()を使用する必要があります。これによってクエリがリセットされ、再度実行できるように準備されます。

 

関連

_SQLite_Query

 


#include <SQLite.au3>
#include <SQLite.dll.au3>

Local $hQuery, $aRow, $iSwitch
_SQLite_Startup()
ConsoleWrite("_SQLite_LibVersion=" &_SQLite_LibVersion() & @CRLF)
_SQLite_Open()
_SQLite_Exec(-1,"CREATE TABLE tblTest (a,b,c);")
_SQLite_Exec(-1,"INSERT INTO tblTest VALUES ('1','1','1');" & _ ; Row 1
                "INSERT INTO tblTest VALUES ('2','2','2');" & _ ; Row 2
                "INSERT INTO tblTest VALUES ('3','3','3');")    ; Row 3
_SQLite_Query(-1,"SELECT RowID,* FROM tblTest;",$hQuery)
While _SQLite_FetchData($hQuery,$aRow) = $SQLITE_OK
    $iSwitch = MsgBox(4+64, "Row: " & $aRow[0], $aRow[1] & "," & $aRow[2] & "," & $aRow[3] & @CRLF & _
                            "Continue Looping?")
    If $iSwitch = 6 Then ; はい
        If $aRow[0] = 3 Then _SQLite_QueryReset($hQuery)
    Else ; いいえ
        _SQLite_QueryFinalize($hQuery)
        ExitLoop
    EndIf
WEnd
_SQLite_Close()
_SQLite_Shutdown()