Function Reference

_WordDocAddPicture

ドキュメントに画像を追加します。

#include <Word.au3>
_WordDocAddPicture ( ByRef $o_object, $s_FilePath [, $b_LinkToFile = 0 [, $b_SaveWithDocument = 0 [, $o_Range = ""]]] )

 

パラメータ

$o_object ドキュメントオブジェクトまたはWord.Applicationのオブジェクト変数。
$s_FilePath 画像のパスとファイル名。
$b_LinkToFile [オプション] 画像を作成元のファイルにリンクするかどうかを指定します。
0 = (デフォルト) 画像をファイルの独立したコピーにします
1 = 画像を作成元のファイルにリンクします
$b_SaveWithDocument [オプション] ドキュメントにリンクされた画像を保存するかどうかを指定します。
0 = (デフォルト) ドキュメントにリンクされた画像を保存しません
1 = ドキュメントにリンクされた画像を保存します
$o_Range [オプション] テキスト内で画像が置かれる位置。
"" = (デフォルト) 画像は自動的に配置されます
任意のRangeオブジェク

 

返し値

成功: Word.Applicationを指すオブジェクト変数、Shapeオブジェクトを返します
失敗: 0を返し@ERROR = 1を設定します
@Error: $_WordStatus_Success = 正常終了
$_WordStatus_GeneralError = 一般的なエラー
$_WordStatus_ComError = Comエラー
$_WordStatus_InvalidDataType = 無効なデータ型
$_WordStatus_InvalidObjectType = 無効なオブジェクト型
$_WordStatus_InvalidValue = 無効な値
@Extended: 無効なパラメータの数を格納

 

注意

なし。

 

関連

None.

 


; *******************************************************
; 例 1 - 新しい空のドキュメントでWordウィンドウを作成、
;               ドキュメントに画像を追加する
; *******************************************************
;
#include <Word.au3>

$sPath = @WindowsDir & "\"
$search = FileFindFirstFile($sPath & "*.bmp")

; 検索が成功したかを調べる
If $search = -1 Then
    MsgBox(0, "Error", "No images found")
    Exit
EndIf

$oWordApp = _WordCreate ()
$oDoc = _WordDocGetCollection ($oWordApp, 0)

While 1
    $file = FileFindNextFile($search)
    If @error Then ExitLoop
    $oShape = _WordDocAddPicture ($oDoc, $sPath & $file, 0, 1)
    If Not @error Then $oShape.Range.InsertAfter (@CRLF)
WEnd

; 検索ハンドルを閉じる
FileClose($search)