Function Reference

_Date_Time_GetTimeZoneInformation

現在のタイムゾーン設定を取得します。

#Include <Date.au3>
_Date_Time_GetTimeZoneInformation()

パラメータ

なし。

返し値

次の形式の配列を返します。
    [0] - 夏時間設定。次のうちのいずれか。
    -1 - 失敗
    0 - 現在のタイムゾーンでは夏時間は使われていません。
    1 - 標準時での夏時間操作
    2 - 夏時間時での夏時間操作
    [1] - このコンピュータでの現在のローカル時刻変換用のバイアス。このバイアスは協定世界時(UTC)とローカル時刻との分差です。 UTCとローカル時刻間の変換は常に次の式に従います。UTC = ローカル時刻 + バイアス。
    [2] - 標準時用説明情報
    [3] - 標準時へ時間加算した夏時間からの変換をおこなう日付けとローカル時刻を格納した$tagSYSTEMTIME構造体
    [4] - 標準時中に起きるローカル時刻変換時に使用されるバイアス値。この値は標準時中に使用されるバイアスを作成するためにBias値に加算されます。ほとんどのタイムゾーンでこの値はゼロです。
    [5] - 夏時間用説明情報
    [6] - 標準時から夏時間への変換をおこなう日付けとローカル時刻を格納した$tagSYSTEMTIME構造体
    [7] - 夏時間中に起きるローカル時刻変換時に使用されるバイアス値。この値は夏時間中に使用されるバイアスを作成するためにバイアスメンバー値に加算されます。ほとんどのタイムゾーンでこの値は-60です。

注意

$tagSYSTEMTIME構造体ではメンバーのwHourとwMinuteは遷移時間を、wDayOfWeekはそれぞれの曜日を、 wDayはその月のうちの曜日の回数を表します（1から5。月のうちその曜日が5回無い場合、5は最後の曜日を表します）。

4月の最初の日曜日の 02:00 を指定する場合は wHour = 2, wMonth = 4, wDayOfWeek = 0, wDay = 1 という表記を使用してください。 10月の最後の木曜日の 02:00 を指定する場合は次のようにします:wHour = 2, wMonth = 10, wDayOfWeek = 4, wDay = 5

例

#include <GuiConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

; Vista では WindowsAPI "SetTimeZoneInformation" はシステムセキュリティによって拒否されることがある

Global $iMemo

_Main()

Func _Main()
Local $hGUI, $aOld, $aNew

; GUIを作成
$hGUI = GUICreate("Time", 400, 300)
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

; 現在のタイムゾーン情報を表示
$aOld = _Date_Time_GetTimeZoneInformation ()
ShowTimeZoneInformation($aOld,"Current")

; 新しいタイムゾーン情報を設定
If Not _Date_Time_SetTimeZoneInformation ($aOld[1], "A3L CST", $aOld[3], $aOld[4], "A3L CDT", $aOld[6], $aOld[7]) Then
MsgBox(4096, "Error", "System timezone cannot be SET" & @CRLF & @CRLF & _WinAPI_GetLastErrorMessage())
Exit
EndIf

; 新しいタイムゾーン情報を表示
$aNew = _Date_Time_GetTimeZoneInformation ()
ShowTimeZoneInformation($aNew, "New")

; 元のタイムゾーン情報にリセット
_Date_Time_SetTimeZoneInformation ($aOld[1], $aOld[2], $aOld[3], $aOld[4], $aOld[5], $aOld[6], $aOld[7])

; 現在のタイムゾーン情報を表示
$aOld = _Date_Time_GetTimeZoneInformation ()
ShowTimeZoneInformation($aOld, "Reset")

; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; メモコントロールに1行書き込む
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; タイムゾーン情報を表示
Func ShowTimeZoneInformation(ByRef $aInfo, $comment)
MemoWrite("******************* " & $comment & " *******************")
MemoWrite("Result ............: " & $aInfo[0])
MemoWrite("Current bias ......: " & $aInfo[1])
MemoWrite("Standard name .....: " & $aInfo[2])
MemoWrite("Standard date/time : " & _Date_Time_SystemTimeToDateTimeStr ($aInfo[3]))
MemoWrite("Standard bias......: " & $aInfo[4])
MemoWrite("Daylight name .....: " & $aInfo[5])
MemoWrite("Daylight date/time : " & _Date_Time_SystemTimeToDateTimeStr ($aInfo[6]))
MemoWrite("Daylight bias......: " & $aInfo[7])
EndFunc   ;==>ShowTimeZoneInformation

日付け管理一覧

AutoItUDFsドキュメント日本語訳 - トップ