指定したExcelオブジェクトのアクティブなワークシート上のセルに情報を書き込みます。
#Include <Excel.au3>
_ExcelWriteCell($oExcel, $sValue, $sRangeOrRow [, $iColumn = 1])
パラメータ
| $oExcel | _ExcelBookOpen()か_ExcelBookNew()の呼び出しで開かれているExcelオブジェクト |
| $sValue | 書き込む値 |
| $sRangeOrRow | A1参照形式での範囲、R1C1参照形式を使用している場合は書き込み位置の整数の行番号 |
| $iColumn | [オプション]R1C1参照形式を使用している場合は書き込む列(デフォルトは1) |
返し値
| 成功: | 1 |
| 失敗: | 0を返し@Errorに値を設定します |
| @error: | 0 - 正常終了 |
| 1 -指定されたオブジェクトが存在しません | |
| 2 - 範囲外のパラメータです | |
| @extended: | 0 -範囲外の行です |
| 1 - 範囲外の列です |
注意
なし。
関連
例
; ***************************************************************
; 例 1 - ワークブックを開きオブジェクト識別子取得後、セルに書き込む。その後、ファイルを保存して閉じる
; *****************************************************************
#include <Excel.au3>
Local $oExcel = _ExcelBookNew() ;新しいブックを作成して表示
_ExcelWriteCell($oExcel, "I Wrote to This Cell", 1, 1) ;セルに書き込み
MsgBox(0, "Exiting", "Press OK to Save File and Exit")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; 上書き設定でtempディレクトリに保存
_ExcelBookClose($oExcel) ; 閉じて終わり
; ***************************************************************
; 例 2 - ワークブックを開きオブジェクト識別子取得後、ループを使ってセルに書き込む。その後、ファイルを保存して閉じる
; *****************************************************************
#include <Excel.au3>
Local $oExcel = _ExcelBookNew() ;新しいブックを作成して表示
For $i = 1 To 20 ;ループ
_ExcelWriteCell($oExcel, "I Wrote to This Cell", $i, 1) ;セルに書き込み
Next
MsgBox(0, "Exiting", "Press OK to Save File and Exit")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; 上書き設定でtempディレクトリに保存
_ExcelBookClose($oExcel) ; 閉じて終わり
; ***************************************************************
; 例 3 - ワークブックを開きオブジェクト識別子取得後、ループを使ってセルに書き込む。_ExcelWriteCellを使って数式を入力する
; *****************************************************************
#include <Excel.au3>
Local $oExcel = _ExcelBookNew() ;新しいブックを作成して表示
For $i = 1 To 20 ;ループ
_ExcelWriteCell($oExcel, $i, $i, 1) ;セルに書き込み
Next
_ExcelWriteCell($oExcel, "=Average(A:A)", 1, 2) ;R1C1参照形式ではなくA1参照形式を使用
_ExcelWriteCell($oExcel, "=Average(A1:A20)", 1, 3) ;もう１つの数式の書き方。;R1C1参照形式ではなくA1参照形式を使用
MsgBox(0, "Exiting", "Press OK to Save File and Exit")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; 上書き設定でtempディレクトリに保存
_ExcelBookClose($oExcel) ; 閉じて終わり