矢尻の高さを取得します。
#Include <GDIPlus.au3>
_GDIPlus_ArrowCapGetHeight($hArrowCap)
パラメータ
| $hArrowCap | ArrowCapオブジェクトのハンドル |
返し値
| 成功: | 矢尻の高さを返します |
| 失敗: | 0 |
注意
ここでの高さとは矢尻の根元から先端までの距離のことです。
関連
_GDIPlus_ArrowCapSetHeight
こちらも参照
MSDNライブラリでGdipGetAdjustableArrowCapHeightを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hGraphic, $hPen, $hEndCap
; GUI作成
$hGUI = GUICreate("GDI+", 400, 300)
GUISetState()
; リソースを作成
_GDIPlus_Startup ()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
$hPen = _GDIPlus_PenCreate (0xFF000000, 4)
$hEndCap = _GDIPlus_ArrowCapCreate (3, 6)
_GDIPlus_PenSetCustomEndCap ($hPen, $hEndCap)
; 矢印1を描画
_GDIPlus_GraphicsDrawLine ($hGraphic, 10, 120, 390, 120, $hPen)
; 矢印2を描画
_GDIPlus_ArrowCapSetHeight ($hEndCap, _GDIPlus_ArrowCapGetHeight ($hEndCap) + 2)
_GDIPlus_PenSetCustomEndCap ($hPen, $hEndCap)
_GDIPlus_GraphicsDrawLine ($hGraphic, 10, 150, 390, 150, $hPen)
; 矢印3を描画
_GDIPlus_ArrowCapSetHeight ($hEndCap, _GDIPlus_ArrowCapGetHeight ($hEndCap) + 2)
_GDIPlus_PenSetCustomEndCap ($hPen, $hEndCap)
_GDIPlus_GraphicsDrawLine ($hGraphic, 10, 180, 390, 180, $hPen)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; リソースを破棄
_GDIPlus_ArrowCapDispose ($hEndCap)
_GDIPlus_PenDispose ($hPen)
_GDIPlus_GraphicsDispose ($hGraphic)
_GDIPlus_Shutdown ()
EndFunc ;==>_Main