ビットマップのハンドルからBitmapオブジェクトを作成します。
#Include <GDIPlus.au3>
_GDIPlus_BitmapCreateFromHBITMAP($hBmp[, $hPal = 0])
パラメータ
$hBmp | HBITMAPハンドル |
$hPal | HPALETTEハンドル |
返し値
成功: | Bitmapオブジェクトのハンドル |
失敗: | 0 |
注意
Bitmapオブジェクトの使用後は_GDIPlus_BitmapDisposeを呼んでリソースを解放してください。
関連
_WinAPI_DeleteObject
こちらも参照
MSDNライブラリでGdipCreateBitmapFromHBITMAPを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hBMP, $hBitmap, $hGraphic
; スクリーンの左上隅をキャプチャ
$hBMP = _ScreenCapture_Capture ("", 0, 0, 400, 300)
; GUI作成
$hGUI = GUICreate("GDI+", 400, 300)
GUISetState()
; GDI+ライブラリを初期化
_GDIPlus_Startup ()
; ビットマップをGUIに描画
$hBitmap = _GDIPlus_BitmapCreateFromHBITMAP ($hBMP)
$hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
_GDIPlus_GraphicsDrawImage ($hGraphic, $hBitmap, 0, 0)
; リソースを破棄
_GDIPlus_GraphicsDispose ($hGraphic)
_GDIPlus_BitmapDispose ($hBitmap)
_WinAPI_DeleteObject ($hBMP)
; GDI+ライブラリを閉じる
_GDIPlus_ShutDown ()
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main