ソリッドブラシオブジェクトの色を設定します。
#Include <GDIPlus.au3>
_GDIPlus_BrushSetSolidColor($hBrush, [$iARGB = 0xFF000000])
パラメータ
| $hBrush | Brushオブジェクトのハンドル |
| $iARGB | [オプション] ブラシのアルファ成分、赤成分、緑成分、青成分 |
返し値
| 成功: | True |
| 失敗: | False |
注意
なし。
関連
こちらも参照
MSDNライブラリでGdipSetSolidFillColorを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $Label1, $label2, $hGraphic, $hBrush1, $iClr1, $iClr2
; GUIを作成
$hGUI = GUICreate("GDI+", 345, 150)
$Label1 = GUICtrlCreateLabel("", 2, 2, 150, 20)
$label2 = GUICtrlCreateLabel("", 202, 2, 150, 20)
GUISetState()
Sleep(100)
; GDIPlusを開始
_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
; ソリッドなブラシを作成
$hBrush1 = _GDIPlus_BrushCreateSolid()
; ソリッドなブラシの元の色を取得
$iClr1 = _GDIPlus_BrushGetSolidColor($hBrush1)
; 元のブラシ色で図形を描画
_GDIPlus_GraphicsFillEllipse($hGraphic, 25, 25, 100, 100, $hBrush1)
; 新しいブラシ色を設定 (0xFFFF0000 = 赤)
_GDIPlus_BrushSetSolidColor($hBrush1, 0xFFFF0000)
; ソリッドなブラシの新しい色を取得
$iClr2 = _GDIPlus_BrushGetSolidColor($hBrush1)
; 新しいブラシ色で図形を描画
_GDIPlus_GraphicsFillRect($hGraphic, 220, 25, 100, 100, $hBrush1)
; 元のブラシ色をラベル1に出力
GUICtrlSetData($Label1, "Brush orignal color: " & Hex($iClr1))
; 新しいブラシ色をラベル2に出力
GUICtrlSetData($label2, "Brush new color: " & Hex($iClr2))
; ユーザーが終了させるまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; リソースを破棄
_GDIPlus_BrushDispose($hBrush1)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()
EndFunc ;==>_Main