利用可能な画像デコーダの情報を配列で取得します。
#Include <GDIPlus.au3>
_GDIPlus_Decoders()
パラメータ
なし。
返し値
| 成功: | 次のフォーマットの配列: |
| [0][ 0] - デコーダの数 | |
| [1][ 1] - コーデック識別子 | |
| [1][ 2] - ファイルフォーマット識別子 | |
| [1][ 3] - コーデック名 | |
| [1][ 4] - コードの存在するDll | |
| [1][ 5] - コーデックで使用されるファイルフォーマット名 | |
| [1][ 6] - コーデックに関連付けられているファイル拡張子名 | |
| [1][ 7] - コーデックのMIMEタイプ | |
| [1][ 8] - $GDIP_ICFフラグの組み合わせ | |
| [1][ 9] - コーデックのバージョン | |
| [1][10] - ファイルフォーマットで使用されているシグネチャの数 | |
| [1][11] - 各シグネチャのバイト数 | |
| [1][12] - 各シグネチャのパターンへのポインタ | |
| [1][13] - 各シグネチャのマスクへのポインタ | |
| Failure: | @errorが設定されます |
注意
なし。
関連
_GDIPlus_Encoders
こちらも参照
MSDNライブラリでGdipGetImageDecodersを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
Global $iMemo, $aEncoder, $hImage
_Main()
Func _Main()
Local $hGUI, $hBitmap
; GUI作成
$hGUI = GUICreate("GDI+", 600, 400)
$iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; GDI+ライブラリを初期化
_GDIPlus_Startup ()
; パラメータリストで使用される画像を作成
$hBitmap = _ScreenCapture_Capture ("", 0, 0, 1, 1)
$hImage = _GDIPlus_BitmapCreateFromHBITMAP ($hBitmap)
; エンコーダのパラメータを表示
$aEncoder = _GDIPlus_Encoders ()
ShowEncoder("Encoder")
; デコーダのパラメータを表示
$aEncoder = _GDIPlus_Decoders ()
ShowEncoder("Decoder")
; リソースを破棄
_GDIPlus_ImageDispose ($hImage)
_WinAPI_DeleteObject ($hBitmap)
; GDI+ライブラリを閉じる
_GDIPlus_ShutDown ()
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; メモコントロールに1行書き込み
Func MemoWrite($sMessage = '')
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite
; エンコーダの情報を表示
Func ShowEncoder($sTitle)
Local $iI, $iJ, $iK, $sCLSID, $tData, $tParam, $tParams
For $iI = 1 To $aEncoder[0][0]
$sCLSID = _GDIPlus_EncodersGetCLSID ($aEncoder[$iI][5])
MemoWrite("Image " & $sTitle & " " & $iI)
MemoWrite(" Codec GUID ............: " & $aEncoder[$iI][ 1])
MemoWrite(" File format GUID ......: " & $aEncoder[$iI][ 2])
MemoWrite(" Codec name ............: " & $aEncoder[$iI][ 3])
MemoWrite(" Codec Dll file name ...: " & $aEncoder[$iI][ 4])
MemoWrite(" Codec file format .....: " & $aEncoder[$iI][ 5])
MemoWrite(" File name extensions ..: " & $aEncoder[$iI][ 6])
MemoWrite(" Mime type .............: " & $aEncoder[$iI][ 7])
MemoWrite(" Flags .................: 0x" & Hex($aEncoder[$iI][ 8]))
MemoWrite(" Version ...............: " & $aEncoder[$iI][ 9])
MemoWrite(" Signature count .......: " & $aEncoder[$iI][10])
MemoWrite(" Signature size ........: " & $aEncoder[$iI][11])
MemoWrite(" Signature pattern ptr .: 0x" & Hex($aEncoder[$iI][12]))
MemoWrite(" Signature mask ptr ....: 0x" & Hex($aEncoder[$iI][13]))
MemoWrite(" Paramater list size ...: " & _GDIPlus_EncodersGetParamListSize ($hImage, $sCLSID))
MemoWrite()
$tParams = _GDIPlus_EncodersGetParamList ($hImage, $sCLSID)
If @error Then ContinueLoop
For $iJ = 0 To DllStructGetData($tParams, "Count") - 1
MemoWrite(" Image " & $sTitle & " Parameter " & $iJ)
$tParam = DllStructCreate($tagGDIPENCODERPARAM, DllStructGetPtr($tParams, "Params") + ($iJ * 28))
MemoWrite(" Parameter GUID ......: " & _WinAPI_StringFromGUID (DllStructGetPtr($tParam, "GUID")))
MemoWrite(" Number of values ....: " & DllStructGetData($tParam, "Count"))
MemoWrite(" Parameter type.......: " & DllStructGetData($tParam, "Type"))
MemoWrite(" Parameter pointer ...: 0x" & Hex(DllStructGetData($tParam, "Values")))
Switch DllStructGetData($tParam, "Type")
Case 4
$tData = DllStructCreate("int Data[" & DllStructGetData($tParam, "Count") & "]", DllStructGetData($tParam, "Values"))
For $iK = 1 To DllStructGetData($tParam, "Count")
MemoWrite(" Value .............: " & DllStructGetData($tData, 1, $iK))
Next
Case 6
$tData = DllStructCreate("int Low;int High", DllStructGetData($tParam, "Values"))
MemoWrite(" Low range .........: " & DllStructGetData($tData, "Low"))
MemoWrite(" High range ........: " & DllStructGetData($tData, "High"))
EndSwitch
MemoWrite()
Next
Next
EndFunc ;==>ShowEncoder