指定された場所に画像を描画します。
#Include <GDIPlus.au3>
_GDIPlus_DrawImagePoints($hGraphic, $hImage, $nULX, $nULY, $nURX, $nURY, $nLLX, $nLLY[, $count = 3])
パラメータ
| $hGraphic | Graphicsオブジェクトのハンドル |
| $hImage | Imageオブジェクトのハンドル |
| $nULX | ソース画像の左上隅のX座標 |
| $nULY | ソース画像の左上隅のY座標 |
| $nURX | ソース画像の右上隅のX座標 |
| $nURY | ソース画像の右上隅のY座標 |
| $nLLX | ソース画像の左下隅のX座標 |
| $nLLY | ソース画像の左下隅のY座標 |
| $count | [オプション]構造体内の点(x,y)の数を指定します |
返し値
| 成功: | True |
| 失敗: | False |
注意
平行四辺形の左上隅、右上隅、左下隅の座標を指定するためにはcountパラメータの値は3でなければなりません。
関連
こちらも参照
MSDNライブラリでGdipDrawImagePointsを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphic
; GDI+ライブラリを初期化
_GDIPlus_Startup()
; フルスクリーンをキャプチャ
$hBitmap1 = _ScreenCapture_Capture("")
$hImage1 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap1)
; スクリーン領域をキャプチャ
$hBitmap2 = _ScreenCapture_Capture("", 0, 0, 400, 300)
$hImage2 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap2)
; 画像を他の画像内に描画
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage1)
_GDIPlus_DrawImagePoints($hGraphic, $hImage2, 100, 100, 600, 170, 130, 570)
; 挿入された画像の周りにフレームを描画
_GDIPlus_GraphicsDrawRect($hGraphic, 100, 100, 400, 300)
; 結果画像を保存
_GDIPlus_ImageSaveToFile($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")
; リソースを破棄
_GDIPlus_ImageDispose($hImage1)
_GDIPlus_ImageDispose($hImage2)
_WinAPI_DeleteObject($hBitmap1)
_WinAPI_DeleteObject($hBitmap2)
; GDI+ライブラリを閉じる
_GDIPlus_Shutdown()
EndFunc ;==>_Main