Fontオブジェクトを作成します。
#Include <GDIPlus.au3>
_GDIPlus_FontCreate($hFamily, $fSize[, $iStyle = 0[, $iUnit = 3]])
パラメータ
| $hFamily | FontFamilyオブジェクトのハンドル |
| $fSize | $iUnitパラメータで指定された単位で測ったフォントのサイズ |
| $iStyle | [オプション]書体のスタイル。次のものの組み合わせです: 0 - 通常の太さ 1 - 太字 2 - 斜体 4 - 下線付き 8 - 取り消し線付き |
| $iUnit | [オプション]フォントサイズの計測単位: 0 - ワールド座標系、非物理単位 1 - 表示単位系 2 - 単位は1ピクセルです 3 - 単位は1ポイントまたは1/72インチです 4 - 単位は1インチです 5 - 単位は1/300インチです 6 - 単位は1ミリメートルです |
返し値
| 成功: | Fontオブジェクトのハンドル |
| 失敗: | 0 |
注意
Fontオブジェクトの使用後は_GDIPlus_FontDispose関数を呼んでリソースを解放してください。
関連
_GDIPlus_FontDispose
こちらも参照
MSDNライブラリでGdipCreateFontを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hWnd, $hGraphic, $hBrush, $hFormat, $hFamily, $hFont, $tLayout
; GUI作成
$hGUI = GUICreate("GDI+", 400, 300)
$hWnd = WinGetHandle("GDI+")
GUISetState()
; 文字列を描画
_GDIPlus_Startup ()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hWnd)
$hBrush = _GDIPlus_BrushCreateSolid (0x7F00007F)
$hFormat = _GDIPlus_StringFormatCreate ()
$hFamily = _GDIPlus_FontFamilyCreate ("Arial")
$hFont = _GDIPlus_FontCreate ($hFamily, 12, 2)
$tLayout = _GDIPlus_RectFCreate (140, 110, 100, 20)
_GDIPlus_GraphicsDrawStringEx ($hGraphic, "Hello world", $hFont, $tLayout, $hFormat, $hBrush)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; リソースを破棄
_GDIPlus_FontDispose ($hFont)
_GDIPlus_FontFamilyDispose ($hFamily)
_GDIPlus_StringFormatDispose ($hFormat)
_GDIPlus_BrushDispose ($hBrush)
_GDIPlus_GraphicsDispose ($hGraphic)
_GDIPlus_Shutdown ()
EndFunc ;==>_Main