Imageオブジェクトを描画します。
#Include <GDIPlus.au3>
_GDIPlus_GraphicsDrawImage($hGraphics, $hImage, $iX, $iY)
パラメータ
$hGraphics | Graphicsオブジェクトのハンドル |
$hImage | Imageオブジェクトのハンドル |
$iX | 描画される画像の左上隅のX座標 |
$iY | 描画される画像の左上隅のY座標 |
返し値
成功: | True |
失敗: | False |
注意
なし。
関連
こちらも参照
MSDNライブラリでGdipDrawImageIを検索して下さい。
例
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphic
; GDI+ライブラリを初期化
_GDIPlus_Startup ()
; フルスクリーンをキャプチャ
$hBitmap1 = _ScreenCapture_Capture ("")
$hImage1 = _GDIPlus_BitmapCreateFromHBITMAP ($hBitmap1)
; スクリーン領域をキャプチャ
$hBitmap2 = _ScreenCapture_Capture ("", 0, 0, 400, 300)
$hImage2 = _GDIPlus_BitmapCreateFromHBITMAP ($hBitmap2)
; 画像を他の画像内に描画
$hGraphic = _GDIPlus_ImageGetGraphicsContext ($hImage1)
_GDIPlus_GraphicsDrawImage ($hGraphic, $hImage2, 100, 100)
; 挿入された画像の周りにフレームを描画
_GDIPlus_GraphicsDrawRect ($hGraphic, 100, 100, 400, 300)
; 結果画像を保存
_GDIPlus_ImageSaveToFile ($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")
; リソースを破棄
_GDIPlus_ImageDispose ($hImage1)
_GDIPlus_ImageDispose ($hImage2)
_WinAPI_DeleteObject ($hBitmap1)
_WinAPI_DeleteObject ($hBitmap2)
; GDI+ライブラリを閉じる
_GDIPlus_ShutDown ()
EndFunc ;==>_Main