多角形を描画します。
#Include <GDIPlus.au3>
_GDIPlus_GraphicsDrawPolygon($hGraphics, $aPoints[, $hPen = 0])
パラメータ
| $hGraphics | Graphicsオブジェクトのハンドル |
| $aPoints | 多角形の頂点を指定する配列: [0][0] - 頂点の数 [1][0] - 頂点1のX座標 [1][1] - 頂点1のY座標 [2][0] - 頂点2のX座標 [2][1] - 頂点2のY座標 [n][0] - 頂点nのX座標 [n][1] - 頂点nのY座標 |
| $hPen | [オプション]多角形の描画に使用されるペンのハンドル。0の場合、幅1の黒いペンが使用されます。 |
返し値
| 成功: | True |
| 失敗: | False |
注意
始点と終点が一致しない場合、その間に直線が描画され多角形が閉じます。
関連
こちらも参照
MSDNライブラリでGdipDrawPolygonIを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hGraphic, $aPoints[4][2]
; GUI作成
$hGUI = GUICreate("GDI+", 400, 300)
GUISetState()
; 多角形を描画
_GDIPlus_Startup ()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
$aPoints[0][0] = 3
$aPoints[1][0] = 150
$aPoints[1][1] = 150
$aPoints[2][0] = 200
$aPoints[2][1] = 100
$aPoints[3][0] = 250
$aPoints[3][1] = 150
_GDIPlus_GraphicsDrawPolygon ($hGraphic, $aPoints)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; リソースを破棄
_GDIPlus_GraphicsDispose ($hGraphic)
_GDIPlus_Shutdown ()
EndFunc ;==>_Main