画像に格納されているピクセルデータ属性の列挙を返します。
#Include <GDIPlus.au3>
_GDIPlus_ImageGetFlags($hImage)
パラメータ
| $hImage | Imageオブジェクトのハンドル |
返し値
| 成功: | 次のフォーマットの配列 |
| [0] - - ピクセルデータ属性の整数フラグのセット | |
| [1] - - 区切り文字"|"で区切られたピクセルデータ属性の文字列 | |
| 失敗: | 空の配列を返し@errorを設定します。@extended にはエラー位置を設定します。 |
| @error: | 0 - 正常終了 |
| 10 - 無効な画像ハンドル |
注意
@errorが4のエラー時にはGDI+UDFは画像ハンドルの代わりに-1または0を返します。
関連
_GDIPlus_ImageGetPixelFormat
こちらも参照
MSDNライブラリでGdipGetImageFlagsを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>
Opt('MustDeclareVars', 1)
Global $iMemo
_Main()
Func _Main()
Local $hBitmap, $hImage, $aRet
; GUI作成
GUICreate("GDI+", 600, 400)
$iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; GDI+ライブラリを初期化
_GDIPlus_Startup()
; 32ビットのビットマップをキャプチャ
$hBitmap = _ScreenCapture_Capture("")
$hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)
; スクリーンキャプチャのピクセルデータ属性の列挙を表示
$aRet = _GDIPlus_ImageGetFlags($hImage)
$aRet[1] = @CRLF & StringReplace($aRet[1], "|", @CRLF)
MemoWrite("Image pixel data attributes of screen capture: " & $aRet[1]);
MemoWrite();
MemoWrite("Image flag set of pixel data attributes: " & $aRet[0]);
MemoWrite();
; スクリーンキャプチャビットマップをファイルに保存
_GDIPlus_ImageSaveToFile($hImage, @MyDocumentsDir & "\GDIPlus_Image.jpg")
; リソースを破棄
_GDIPlus_ImageDispose($hImage)
_WinAPI_DeleteObject($hBitmap)
; スクリーンキャプチャビットマップをファイルからロード
$hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")
; 保存されたファイルのピクセルデータ属性の列挙を表示
$aRet = _GDIPlus_ImageGetFlags($hImage)
$aRet[1] = @CRLF & StringReplace($aRet[1], "|", @CRLF)
MemoWrite("Image pixel data attributes of saved file: " & $aRet[1]);
MemoWrite();
MemoWrite("Image flag set of pixel data attributes: " & $aRet[0]);
; リソースを破棄
_GDIPlus_ImageDispose($hImage)
; GDI+ライブラリを閉じる
_GDIPlus_Shutdown()
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; メモコントロールに1行書き込み
Func MemoWrite($sMessage = '')
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite