画像のグラフィックコンテキストを取得します。
#Include <GDIPlus.au3>
_GDIPlus_ImageGetGraphicsContext($hImage)
パラメータ
| $hImage | Imageオブジェクトのハンドル |
返し値
| 成功: | Graphicsオブジェクトのハンドル |
| 失敗: | -1が返され@errorが設定されます |
注意
なし。
関連
こちらも参照
MSDNライブラリでGdipGetImageGraphicsContextを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphics
; GDI+ライブラリを初期化
_GDIPlus_Startup ()
; フルスクリーンをキャプチャ
$hBitmap1 = _ScreenCapture_Capture ("")
$hImage1 = _GDIPlus_BitmapCreateFromHBITMAP ($hBitmap1)
; スクリーン領域をキャプチャ
$hBitmap2 = _ScreenCapture_Capture ("", 0, 0, 400, 300)
$hImage2 = _GDIPlus_BitmapCreateFromHBITMAP ($hBitmap2)
; 画像を他の画像内に描画
$hGraphics = _GDIPlus_ImageGetGraphicsContext ($hImage1)
_GDIPlus_GraphicsDrawImage ($hGraphics, $hImage2, 100, 100)
; 挿入された画像の周りにフレームを描画
_GDIPlus_GraphicsDrawRect ($hGraphics, 100, 100, 400, 300)
; 結果画像を保存
_GDIPlus_ImageSaveToFile ($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")
; リソースを破棄
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_ImageDispose ($hImage1)
_GDIPlus_ImageDispose ($hImage2)
_WinAPI_DeleteObject ($hBitmap1)
_WinAPI_DeleteObject ($hBitmap2)
; GDI+ライブラリを閉じる
_GDIPlus_ShutDown ()
EndFunc ;==>_Main