画像をファイルに保存します。
#Include <GDIPlus.au3>
_GDIPlus_ImageSaveToFileEx($hImage, $sFileName, $sEncoder[, $pParams = 0])
パラメータ
| $hImage | Imageオブジェクトのハンドル |
| $sFileName | 完全修飾された画像ファイル名 |
| $sEncoder | 使用されるエンコーダのGUID文字列 |
| $pParams | [オプション]$tagGDIPPENCODERPARAMS構造体へのポインタ |
返し値
| 成功: | True |
| 失敗: | False |
注意
なし。
関連
_GDIPlus_ImageLoadFromFile, _GDIPlus_ImageSaveToFile, $tagGDIPPENCODERPARAMS
こちらも参照
MSDNライブラリでGdipSaveImageToFileを検索して下さい。
例
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hBitmap, $hImage, $sCLSID, $tData, $tParams
; スクリーンをキャプチャ
_ScreenCapture_Capture (@MyDocumentsDir & "\GDIPlus_Image.jpg")
; GDI+ライブラリを初期化
_GDIPlus_Startup ()
; 画像をロード
$hImage = _GDIPlus_ImageLoadFromFile (@MyDocumentsDir & "\GDIPlus_Image.jpg")
; JPEGエンコーダのCLSIDを取得
$sCLSID = _GDIPlus_EncodersGetCLSID ("JPG")
; パラメータに90度回転を設定
$tData = DllStructCreate("int Data")
DllStructSetData($tData, "Data", $GDIP_EVTTRANSFORMROTATE90)
$tParams = _GDIPlus_ParamInit (1)
_GDIPlus_ParamAdd ($tParams, $GDIP_EPGTRANSFORMATION, 1, $GDIP_EPTLONG, DllStructGetPtr($tData, "Data"))
; 回転した画像を保存
_GDIPlus_ImageSaveToFileEx ($hImage, @MyDocumentsDir & "\GDIPlus_Image2.jpg", $sCLSID, DllStructGetPtr($tParams))
; GDI+ライブラリを閉じる
_GDIPlus_ShutDown ()
EndFunc ;==>_Main