Function Reference

_GDIPlus_ParamAdd

エンコーダパラメータリストに値を追加します。

#Include <GDIPlus.au3>
_GDIPlus_ParamAdd(ByRef $tParams, $sGUID, $iCount, $iType, $pValues)

 

パラメータ

$tParams _GDIPlus_ParamInitの返す$tagGDIPPENCODERPARAMS構造体
$sGUID エンコーダパラメータGUID。次のいずれかです:
$ GDIP_EPGCHROMINANCETABLE - クロミナンステーブルの設定
$ GDIP_EPGCOLORDEPTH - 色深度の設定
$ GDIP_EPGCOMPRESSION - 圧縮の設定
$ GDIP_EPGLUMINANCETABLE - 輝度テーブルの設定
$ GDIP_EPGQUALITY - 品質の設定
$ GDIP_EPGRENDERMETHOD - 描画方法の設定
$ GDIP_EPGSAVEFLAG - 保存フラグ設定
$ GDIP_EPGSCANMETHOD - スキャンモードの設定
$ GDIP_EPGTRANSFORMATION - 変換の設定
$ GDIP_EPGVERSION - ソフトウェアバージョンの設定
$iCount $pValues配列の要素数
$iType エンコーダパラメータの値の種類。次のいずれかです:
$ GDIP_EPTBYTE - 8ビット符号なし整数
$ GDIP_EPTASCII - NULL文字で終わる文字列
$ GDIP_EPTSHORT - 16ビット符号なし整数
$ GDIP_EPTLONG - 32ビット符号なし整数
$ GDIP_EPTRATIONAL - 2つのlong型(分子、分母)
$ GDIP_EPTLONGRANGE - 2つのlong型(低、高)
$ GDIP_EPTUNDEFINED - 任意の型のバイト配列
$ GDIP_EPTRATIONALRANGE - 2つの有理数(低、高)
$pValues 値の配列へのポインタ。各値は$iTypeデータメンバーで指定された種類です。

 

返し値

なし。

 

注意

なし。

 

関連

_GDIPlus_ParamInit, $tagGDIPPENCODERPARAMS

 


#include <GDIPlus.au3>
#include <ScreenCapture.au3>

Opt('MustDeclareVars', 1)

_Main()

Func _Main()
    Local $hBitmap, $hImage, $sCLSID, $tData, $tParams

    ; スクリーンをキャプチャ
    _ScreenCapture_Capture (@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; GDI+ライブラリを初期化
    _GDIPlus_Startup ()

    ; 画像をロード
    $hImage = _GDIPlus_ImageLoadFromFile (@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; JPEGエンコーダのCLSIDを取得
    $sCLSID = _GDIPlus_EncodersGetCLSID ("JPG")

    ; パラメータに90度回転を設定
    $tData = DllStructCreate("int Data")
    DllStructSetData($tData, "Data", $GDIP_EVTTRANSFORMROTATE90)
    $tParams = _GDIPlus_ParamInit (1)
    _GDIPlus_ParamAdd ($tParams, $GDIP_EPGTRANSFORMATION, 1, $GDIP_EPTLONG, DllStructGetPtr($tData, "Data"))

    ; 回転した画像を保存
    _GDIPlus_ImageSaveToFileEx ($hImage, @MyDocumentsDir & "\GDIPlus_Image2.jpg", $sCLSID, DllStructGetPtr($tParams))

    ; GDI+ライブラリを閉じる
    _GDIPlus_ShutDown ()

EndFunc   ;==>_Main