Function Reference

_GUICtrlAVI_IsPlaying

オーディオ-ビデオインターリーブ(AVI)クリップが再生中かどうかを調べます。

#Include <GuiAVI.au3>
_GUICtrlAVI_IsPlaying($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: True
失敗: False

 

注意

必須OS: Windows Vista

 

関連

 

こちらも参照

MSDNライブラリでACM_ISPLAYINGを検索して下さい。

 


#include <GuiConstantsEx.au3>
#include <GuiAVI.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_AVI = False ; AVI関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Global $hAVI, $iMemo

_Main()

Func _Main()
    Local $Wow64 = ""
    If @AutoItX64 Then $Wow64 = "\Wow6432Node"
    Local $hGUI, $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\Examples\GUI\SampleAVI.avi"
    Local $btn_StartStop

    ; GUI作成
    $hGUI = GUICreate("(External) AVI Open", 300, 200)
    $hAVI = _GUICtrlAVI_Create($hGUI, "", -1, 10, 10)
    $btn_StartStop = GUICtrlCreateButton("Start", 50, 10, 75, 25)
    $iMemo = GUICtrlCreateEdit("", 10, 50, 276, 144, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; サンプルのAutoIt AVIを再生
    _GUICtrlAVI_Open($hAVI, $sFile)

    ; ユーザーが終了するまでループ
    While 1
        Switch GUIGetMsg()
            Case $btn_StartStop
                If GUICtrlRead($btn_StartStop) = "Start" Then
                    _GUICtrlAVI_Play($hAVI)
                    GUICtrlSetData($btn_StartStop, "Stop")
                Else
                    _GUICtrlAVI_Stop($hAVI)
                    GUICtrlSetData($btn_StartStop, "Start")
                EndIf
                MemoWrite("Is Playing: " & _GUICtrlAVI_IsPlaying($hAVI))

            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    ; AVIクリップを閉じる
    _GUICtrlAVI_Close($hAVI)


    GUIDelete()
EndFunc   ;==>_Main

; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite