ラジオボタン、チェックボックスのチェックの状態を取得します。
#Include <GuiButton.au3>
_GUICtrlButton_GetCheck($hWnd)
パラメータ
| $hWnd | コントロールのハンドル |
返し値
| 成功: | $BS_AUTOCHECKBOX、$BS_AUTORADIOBUTTON、$BS_AUTO3STATE、$BS_CHECKBOX、$BS_RADIOBUTTON、$BS_3STATEスタイルで作成されたボタンの返し値は次のうちのいずれかです: |
| $BST_CHECKED - ボタンはチェックされています。 | |
| $BST_INDETERMINATE - ボタンは状態未定を表すグレイ状態です($BS_3STATE、$BS_AUTO3STATEスタイルが設定されているボタンのみ)。 | |
| $BST_UNCHECKED - ボタンは取り消し状態です。 | |
| 失敗: | 0 |
注意
ここであげたスタイル以外のボタンはゼロを返します。
関連
_GUICtrlButton_GetState, _GUICtrlButton_SetCheck
こちらも参照
MSDNライブラリでBM_GETCHECKを検索して下さい。
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <WindowsConstants.au3>
Opt("MustDeclareVars", 1)
Global $iMemo
_Main()
Func _Main()
Local $rdo, $rdo2, $chk
GUICreate("Buttons", 400, 400)
$iMemo = GUICtrlCreateEdit("", 119, 10, 276, 374, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
$rdo = GUICtrlCreateRadio("Radio1", 10, 10, 90, 50)
$rdo2 = GUICtrlCreateRadio("Radio2", 10, 60, 90, 50)
_GUICtrlButton_SetCheck($rdo2)
_GUICtrlButton_SetFocus($rdo2) ; フォーカスを設定。これが_GUICtrlButton_GetCheckに影響しないことを示す
$chk = GUICtrlCreateCheckbox("Check1", 10, 120, 90, 50, BitOR($BS_AUTO3STATE, $BS_NOTIFY))
_GUICtrlButton_SetCheck($chk, $BST_INDETERMINATE)
GUISetState()
MemoWrite("$rdo checked status.: " & @CRLF & @TAB & _ExplainCheckState(_GUICtrlButton_GetCheck($rdo)) & @CRLF)
MemoWrite("$rdo2 checked status: " & @CRLF & @TAB & _ExplainCheckState(_GUICtrlButton_GetCheck($rdo2)) & @CRLF)
MemoWrite("$chk checked status.: " & @CRLF & @TAB & _ExplainCheckState(_GUICtrlButton_GetCheck($chk)) & @CRLF)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd
Exit
EndFunc ;==>_Main
; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite
Func _ExplainCheckState($iState)
Switch $iState
Case $BST_CHECKED
Return "Button is checked."
Case $BST_INDETERMINATE
Return "Button is grayed, indicating an indeterminate state (applies only if the button has the $BS_3STATE or $BS_AUTO3STATE style)."
Case $BST_UNCHECKED
Return "Button is cleared"
EndSwitch
EndFunc ;==>_ExplainCheckState