ボタンコントロールに画像リストを割り当てます。
#Include <GuiButton.au3>
_GUICtrlButton_SetImageList($hWnd, $hImage[, $nAlign = 0[, $iLeft = 1[, $iTop = 1[, $iRight = 1[, $iBottom = 1]]]]])
パラメータ
$hWnd | コントロールのハンドル |
$hImage | 画像リストのハンドル。 全ての状態に使用される単一画像または次にリストアップする各状態に対応する個々の画像を格納していなければなりません: 1 - ノーマル 2 - ホット 3 - 押されています 4 - 無効 5 - デフォルト 6 - スタイラスホット (タブレットコンピュータのみ) |
$nAlign | [オプション]使用される位置あわせを指定します。このパラメータは次の値のいずれかです: 0 - 画像を左余白に揃えます 1 - 画像を右余白に揃えます 2 - 画像を上余白に揃えます 3 - 画像を下余白に揃えます 4 - 画像を中央に揃えます |
$iLeft | [オプション]アイコンの左余白 |
$iTop | [オプション]アイコンの上余白 |
$iRight | [オプション]アイコンの右余白 |
$iBottom | [オプション]アイコンの下余白 |
返し値
成功: | True |
失敗: | False |
注意
必須OS: Windows XP以降
関連
_GUICtrlButton_GetImageList
こちらも参照
MSDNライブラリでBCM_SETIMAGELISTを検索して下さい。
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <GuiImageList.au3>
Opt("MustDeclareVars", 1)
_Main()
Func _Main()
Local $hImage, $y = 70, $iIcon = 125, $btn[6], $rdo[6], $chk[6], $hImageSmall
GUICreate("Buttons", 510, 400)
GUISetState()
$hImage = _GUIImageList_Create(32, 32, 5, 3, 6)
For $x = 6 To 11
_GUIImageList_AddIcon($hImage, "shell32.dll", $x, True)
Next
$hImageSmall = _GUIImageList_Create(16, 16, 5, 3, 6)
For $x = 6 To 11
_GUIImageList_AddIcon($hImageSmall, "shell32.dll", $x)
Next
$btn[0] = GUICtrlCreateButton("Button1", 10, 10, 90, 50)
_GUICtrlButton_SetImageList($btn[0], $hImage)
$rdo[0] = GUICtrlCreateRadio("Radio Button1", 120, 10, 120, 25)
_GUICtrlButton_SetImageList($rdo[0], $hImageSmall)
$chk[0] = GUICtrlCreateCheckbox("Check Button1", 260, 10, 120, 25)
_GUICtrlButton_SetImageList($chk[0], $hImageSmall)
For $x = 1 To 5
$btn[$x] = GUICtrlCreateButton("Button" & $x + 1, 10, $y, 90, 50)
_GUICtrlButton_SetImageList($btn[$x], _GetImageListHandle("shell32.dll", $iIcon + $x, True), $x)
$rdo[$x] = GUICtrlCreateRadio("Radio Button" & $x + 1, 120, $y, 120, 25)
_GUICtrlButton_SetImageList($rdo[$x], _GetImageListHandle("shell32.dll", $iIcon + $x), $x)
$chk[$x] = GUICtrlCreateCheckbox("Check Button" & $x + 1, 260, $y, 120, 25)
_GUICtrlButton_SetImageList($chk[$x], _GetImageListHandle("shell32.dll", $iIcon + $x), $x)
$y += 60
Next
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd
Exit
EndFunc ;==>_Main
; ボタンに画像リストを使用して画像を設定、テキストを設定
Func _GetImageListHandle($sFile, $nIconID = 0, $fLarge = False)
Local $iSize = 16
If $fLarge Then $iSize = 32
Local $hImage = _GUIImageList_Create($iSize, $iSize, 5, 3)
If StringUpper(StringMid($sFile, StringLen($sFile) - 2)) = "BMP" Then
_GUIImageList_AddBitmap($hImage, $sFile)
Else
_GUIImageList_AddIcon($hImage, $sFile, $nIconID, $fLarge)
EndIf
Return $hImage
EndFunc ;==>_GetImageListHandle