コンボボックスのリストボックスの許容される最小幅を取得します。
#Include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetDroppedWidth($hWnd)
パラメータ
| $hWnd | コントロールのハンドル |
返し値
| 成功: | ピクセル単位での幅 |
| 失敗: | -1 |
注意
; コンボボックスには$CBS_DROPDOWNスタイルまたは$CBS_DROPDOWNLISTスタイルが設定されている必要があります。
関連
_GUICtrlComboBox_GetDroppedState, _GUICtrlComboBoxEx_SetDroppedWidth
例
#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiConstantsEx.au3>
Opt('MustDeclareVars', 1)
$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hImage, $hCombo
; GUIを作成
$hGUI = GUICreate("ComboBoxEx Get Dropped Width", 400, 300)
$hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
$hImage = _GUIImageList_Create (16, 16, 5, 3)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
_GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)
For $x = 0 To 8
_GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
Next
; ドロップ幅を取得
MemoWrite("Dropped Width......: " & _GUICtrlComboBoxEx_GetDroppedWidth ($hCombo))
Sleep(500)
; ドロップダウン表示
_GUICtrlComboBoxEx_ShowDropDown ($hCombo, True)
Sleep(500)
; ドロップダウン非表示
_GUICtrlComboBoxEx_ShowDropDown ($hCombo)
; ドロップ幅を設定
_GUICtrlComboBoxEx_SetDroppedWidth ($hCombo, 500)
Sleep(500)
; ドロップ幅を取得
MemoWrite("Dropped Width......: " & _GUICtrlComboBoxEx_GetDroppedWidth ($hCombo))
Sleep(500)
; ドロップダウン表示
_GUICtrlComboBoxEx_ShowDropDown ($hCombo, True)
Sleep(500)
; ドロップダウン非表示
_GUICtrlComboBoxEx_ShowDropDown ($hCombo)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite