Function Reference

_GUICtrlComboBoxEx_GetEditSel

コンボボックスのエディットコントロールの現在の選択値の開始、終了文字位置を取得します。

#Include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetEditSel($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: 次のフォーマットの配列:
        [0] - 開始位置
        [1] - 終了位置
失敗: -1

 

注意

$CBS_DROPDOWNスタイルまたは$CBS_DROPDOWNLISTスタイルの設定されたコンボボックスにメッセージが送信された場合、この関数は失敗します。

 

関連

_GUICtrlComboBoxEx_SetEditSel

 


#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hImage, $aSel, $hCombo
   
    ; GUIを作成
    $hGUI = GUICreate("ComboBoxEx Get Edit Sel", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 70, BitOR($CBS_SIMPLE, $WS_VSCROLL, $WS_BORDER))
    $iMemo = GUICtrlCreateEdit("", 2, 72, 396, 226, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    $hImage = _GUIImageList_Create (16, 16, 5, 3)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

    ; 文字列を追加
    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
    Next
   
    ; 現在の選択値を設定
    _GUICtrlComboBoxEx_SetCurSel ($hCombo, Random(0, 8, 1))

    ; エディットの選択部を設定
    _GUICtrlComboBoxEx_SetEditSel ($hCombo, 0, 4)
   
    ; 現在の選択値を取得
    $aSel = _GUICtrlComboBoxEx_GetEditSel ($hCombo)
    MemoWrite(StringFormat("Selected: [%d][%d]", $aSel[0], $aSel[1]))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite