Function Reference

_GUICtrlComboBoxEx_GetItem

アイテムの属性を取得します。

#Include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetItem($hWnd, $iIndex)

 

パラメータ

$hWnd コントロールのハンドル
$iIndex ゼロ始まりのアイテムインデックス

 

返し値

成功: 次のフォーマットの配列:
        [0] - アイテムテキスト
        [1] - アイテムテキストの長さ
        [2] - アイテムをインデントする際の画像幅数
        [3] - ゼロ始まりのアイテムの画像インデックス
        [4] - ゼロ始まりのアイテムの状態画像インデックス
        [5] - ゼロ始まりのアイテムの画像オーバーレイインデックス
        [6] - アイテムのアプリケーション定義値

 

注意

なし。

 

関連

_GUICtrlComboBoxEx_SetItem, _GUICtrlComboBoxEx_GetItemEx

 

例


#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiConstantsEx.au3>

Opt('MustDeclareVars', 1)

$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hImage, $aItem, $hCombo
   
    ; GUIを作成
    $hGUI = GUICreate("ComboBoxEx Get Item", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    $hImage = _GUIImageList_Create (16, 16, 5, 3)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
    Next

    ; アイテムのインデント設定
    _GUICtrlComboBoxEx_SetItemIndent ($hCombo, 1, 1)

    $aItem = _GUICtrlComboBoxEx_GetItem ($hCombo, 1)
    MemoWrite("Item Text : " & $aItem[0])
    MemoWrite("Item Len ..........................: " & $aItem[1])
    MemoWrite("# image widths to indent ..........: " & $aItem[2])
    MemoWrite("Zero based item image index .......: " & $aItem[3])
    MemoWrite("Zero based item state image index .: " & $aItem[4])
    MemoWrite("Zero based item image overlay index: " & $aItem[5])
    MemoWrite("Item application defined value ....: " & $aItem[6])
   
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

 

Gui拡張コンボボックス管理一覧
AutoItUDFsドキュメント日本語訳 - トップ