エディットボックス内の選択テキストを置換します。
#Include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_ReplaceEditSel($hWnd, $sText)
パラメータ
| $hWnd | コントロールのハンドル |
| $sText | 置換テキストを格納している文字列 |
返し値
なし。
注意
$CBS_DROPDOWNスタイルまたは$CBS_DROPDOWNLISTスタイルが設定されたコンボボックスに使用した場合、この関数は失敗します。
関連
_GUICtrlComboBoxEx_SetEditText
例
#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $hGUI, $hImage, $hCombo
; GUIを作成
$hGUI = GUICreate("ComboBoxEx Replace Edit Sel", 400, 300)
$hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100, BitOR($CBS_SIMPLE, $WS_VSCROLL, $WS_BORDER))
GUISetState()
$hImage = _GUIImageList_Create (16, 16, 5, 3)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
_GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)
_GUICtrlComboBoxEx_InitStorage ($hCombo, 150, 300)
_GUICtrlComboBoxEx_BeginUpdate ($hCombo)
For $x = 0 To 149
_GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), Random(0, 8, 1), Random(0, 8, 1), Random(0, 8, 1))
Next
_GUICtrlComboBoxEx_EndUpdate ($hCombo)
; 現在の選択値を設定
_GUICtrlComboBoxEx_SetCurSel ($hCombo, Random(0, 149, 1))
; エディットの選択部を設定
_GUICtrlComboBoxEx_SetEditSel ($hCombo, 0, 4)
Sleep(500)
; エディットの選択部を置換
_GUICtrlComboBoxEx_ReplaceEditSel ($hCombo, "Replaced")
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main