拡張コンボボックスコントロールに拡張スタイルを設定します。
#Include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetExtendedStyle($hWnd, $iExStyle[, $iExMask = 0])
パラメータ
| $hWnd | コントロールのハンドル |
| $iExStyle | コントロールの拡張スタイル: $CBES_EX_CASESENSITIVE - リストの検索で大文字小文字を区別します。 $CBES_EX_NOEDITIMAGE - エディットボックスとドロップダウンリストでアイテム画像を表示しません $CBES_EX_NOEDITIMAGEINDENT - エディットボックスとドロップダウンリストでアイテム画像を表示しません $CBES_EX_NOSIZELIMIT - 拡張コンボボックスコントロールを格納されているコンボボックスコントロールより小さい垂直サイズにできるようにします。 $CBES_EX_PATHWORDBREAKPROC - Microsoft Windows NTのみ。 エディットボックスでスラッシュ(/)、バックスラッシュ(\)、ピリオド(.)を単語区切り文字として使用します。 |
| $iExMask | [オプション]
$iExStyle内のどのスタイルが使用されるかを指定します。このパラメータは拡張スタイルの組み合わせです。
$iExMaskに設定されたの拡張スタイルのみ変更され、他のスタイルは維持されます。 このパラメータがゼロの場合、$iExStyle内のスタイル全てが使用されます。 |
返し値
成功: 直前の拡張スタイル
注意
なし。
関連
_GUICtrlComboBoxEx_GetExtendedStyle
例
#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiConstantsEx.au3>
Opt('MustDeclareVars', 1)
$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $hGUI, $hImage, $hCombo
; GUIを作成
$hGUI = GUICreate("ComboBoxEx Set Extended Style", 400, 300)
$hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
; 拡張スタイルを設定
_GUICtrlComboBoxEx_SetExtendedStyle ($hCombo, $CBES_EX_CASESENSITIVE)
GUISetState()
$hImage = _GUIImageList_Create (16, 16, 5, 3)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
_GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
_GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)
For $x = 0 To 8
_GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
Next
; 拡張スタイルを取得
MsgBox(4160, "Information", "Extend Styles found: " & _DisplayExtendStringList($hCombo))
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
Func _DisplayExtendStringList($hCombo)
Local $Styles = @LF & @LF & @TAB
If (BitAND(_GUICtrlComboBoxEx_GetExtendedStyle ($hCombo), $CBES_EX_CASESENSITIVE) = $CBES_EX_CASESENSITIVE) Then $Styles &= "$CBES_EX_CASESENSITIVE" & @LF & @TAB
If (BitAND(_GUICtrlComboBoxEx_GetExtendedStyle ($hCombo), $CBES_EX_NOEDITIMAGE) = $CBES_EX_NOEDITIMAGE) Then $Styles &= "$CBES_EX_NOEDITIMAGE" & @LF & @TAB
If (BitAND(_GUICtrlComboBoxEx_GetExtendedStyle ($hCombo), $CBES_EX_NOEDITIMAGEINDENT) = $CBES_EX_NOEDITIMAGEINDENT) Then $Styles &= "$CBES_EX_NOEDITIMAGEINDENT" & @LF & @TAB
If (BitAND(_GUICtrlComboBoxEx_GetExtendedStyle ($hCombo), $CBES_EX_NOSIZELIMIT) = $CBES_EX_NOSIZELIMIT) Then $Styles &= "$CBES_EX_NOSIZELIMIT" & @LF & @TAB
If (BitAND(_GUICtrlComboBoxEx_GetExtendedStyle ($hCombo), $CBES_EX_PATHWORDBREAKPROC) = $CBES_EX_PATHWORDBREAKPROC) Then $Styles &= "$CBES_EX_PATHWORDBREAKPROC"
Return $Styles
EndFunc ;==>_DisplayExtendStringList