コンボボックスコントロールを作成します。
#Include <GuiComboBox.au3>
_GUICtrlComboBox_Create($hWnd, $sText, $iX, $iY[, $iWidth = 100[, $iHeight = 120[, $iStyle = 0x00200042[, $iExStyle = 0x00000000]]]])
パラメータ
$hWnd | 親ウィンドウまたはオーナーウィンドウのハンドル |
$sText | コンボボックスに追加する区切られた文字列 |
$iX | コントロールの水平位置 |
$iY | コントロールの垂直位置 |
$iWidth | [オプション]コントロールの幅 |
$iHeight | [オプション]コントロールの高さ |
$iStyle | [オプション]コントロールのスタイル: $CBS_AUTOHSCROLL - ユーザーが行末に文字を入力すると自動でエディットコントロール内のテキストを右にスクロールします。 $CBS_DISABLENOSCROLL - 無効の垂直スクロールバーを表示します。 $CBS_DROPDOWN - ユーザーがエディットコントロールの隣のアイコンを選択しないとリストボックスが表示されない以外は$CBS_SIMPLEと同じです。 $CBS_DROPDOWNLIST - エディットコントロールがリストボックスに現在の選択値として表示されるアイテムのスタティックなテキストで置換される以外は$CBS_DROPDOWNと同じです。 $CBS_LOWERCASE - 選択領域とリスト両方の全テキストを小文字に変換します。 $CBS_NOINTEGRALHEIGHT - コンボボックスのサイズをアプリケーションがコンボボックスを作成する際に指定する正確なサイズにするよう指定します。 $CBS_OEMCONVERT - コンボボックスのエディットコントロールに入力されたテキストをWindows文字セットからOEM文字セットに変換します。またWindows文字セットへの逆変換をおこないます。 $CBS_OWNERDRAWFIXED - リストボックスのオーナーがその内容の描画をおこなうように、またリストボックス内のアイテムを全て同じ高さにするように指定します。 $CBS_OWNERDRAWVARIABLE - リストボックスのオーナーがその内容の描画をおこなうように、またリストボックス内のアイテムの高さを可変にするように指定します。 $CBS_SIMPLE - 常にリストボックスを表示します。 $CBS_SORT - リストボックスに追加される文字列を自動整列させます。 $CBS_UPPERCASE - 選択領域とリスト両方の全テキストを大文字に変換します。 |
デフォルト : $CBS_DROPDOWN、$CBS_AUTOHSCROLL、$WS_VSCROLL 強制 : $WS_CHILD、$WS_TABSTOP、$WS_VISIBLE |
|
$iExStyle | [オプション]コントロールの拡張スタイル。標準の$WS_EX_定数に対応しています。 |
返し値
成功: | リストボックスコントロールのハンドル |
失敗: | 0 |
注意
この関数は上級者、コントロール動作学習用です。
関連
_GUICtrlComboBox_Destroy
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIComboBox.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
Opt('MustDeclareVars', 1)
$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $hCombo
_Main()
Func _Main()
Local $hGUI
; GUIを作成
$hGUI = GUICreate("(UDF) ComboBox Create", 400, 296)
$hCombo = _GUICtrlComboBox_Create($hGUI, "", 2, 2, 396, 296)
GUISetState()
; ファイルを追加
_GUICtrlComboBox_BeginUpdate($hCombo)
_GUICtrlComboBox_AddDir($hCombo, "", $DDL_DRIVES, False)
_GUICtrlComboBox_EndUpdate($hCombo)
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
#forceref $hWnd, $iMsg
Local $hWndFrom, $iIDFrom, $iCode
$hWndFrom = $ilParam
$iIDFrom = BitAND($iwParam, 0xFFFF) ; 下位ワード
$iCode = BitShift($iwParam, 16) ; 上位ワード
Switch $hWndFrom
Case $hCombo
Switch $iCode
Case $CBN_CLOSEUP ; コンボボックスのリストボックスが閉じられる際に送信
_DebugPrint("$CBN_CLOSEUP" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; 返し値なし
Case $CBN_DBLCLK ; ユーザーがコンボボックスのリストボックス内の文字列をダブルクリックした際に送信
_DebugPrint("$CBN_DBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; 返し値なし
Case $CBN_DROPDOWN ; コンボボックスのリストボックスを表示している際に送信
_DebugPrint("$CBN_DROPDOWN" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; 返し値なし
Case $CBN_EDITCHANGE ; コンボボックスのエディットコントロール部分のテキストを変更するような操作をユーザーがおこなった際に送信
_DebugPrint("$CBN_EDITCHANGE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; 返し値なし
Case $CBN_EDITUPDATE ; コンボボックスのエディットコントロール部分が変更されたテキストを表示している際に送信
_DebugPrint("$CBN_EDITUPDATE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; 返し値なし
Case $CBN_ERRSPACE ; コンボボックスが指定された要求に合う十分なメモリの割り当てができなかった際に送信
_DebugPrint("$CBN_ERRSPACE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; 返し値なし
Case $CBN_KILLFOCUS ; コンボボックスからキーボードフォーカスが外れた際に送信
_DebugPrint("$CBN_KILLFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; 返し値なし
Case $CBN_SELCHANGE ; ユーザーがコンボボックスのリストボックスの現在の選択値を変更した際に送信
_DebugPrint("$CBN_SELCHANGE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; 返し値なし
Case $CBN_SELENDCANCEL ; ユーザーがアイテム選択中に他のコントロールを選択したり、ダイアログボックスを閉じた際に送信
_DebugPrint("$CBN_SELENDCANCEL" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; 返し値なし
Case $CBN_SELENDOK ; ユーザーがリストアイテム、アイテム選択中にリストを閉じた際に送信
_DebugPrint("$CBN_SELENDOK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; 返し値なし
Case $CBN_SETFOCUS ; コンボボックスにキーボードフォーカスが合った際に送信
_DebugPrint("$CBN_SETFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
"-->IDFrom:" & @TAB & $iIDFrom & @LF & _
"-->Code:" & @TAB & $iCode)
; 返し値なし
EndSwitch
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_COMMAND
Func _DebugPrint($s_text, $line = @ScriptLineNumber)
ConsoleWrite( _
"!===========================================================" & @LF & _
"+======================================================" & @LF & _
"-->Line(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
"+======================================================" & @LF)
EndFunc ;==>_DebugPrint