Function Reference

_GUICtrlComboBox_FindString

文字列を検索します。

#Include <GuiComboBox.au3>
_GUICtrlComboBox_FindString($hWnd, $sText[, $iIndex = -1])

 

パラメータ

$hWnd コントロールのハンドル
$sText 検索文字列
$iIndex [オプション]検索開始位置のアイテムの1つ前のアイテムのゼロ始まりのインデックス

 

返し値

成功: 一致したアイテムのゼロ始まりのインデックス
失敗: -1

 

注意

$sTextで指定された文字で始まる最初の文字列を見つけ出します。

リストボックスの一番下まで検索が到達した場合、リストボックスの先頭から$iIndexで指定されたアイテムまで検索が継続されます。

$iIndexが-1の場合、リストボックス全体が先頭から検索されます。

 

関連

_GUICtrlComboBox_SelectString

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIComboBox.au3>
#include <GuiConstantsEx.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hCombo

    ; GUIを作成
    GUICreate("ComboBox Find String", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState()

    ; ファイルを追加
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, "", $DDL_DRIVES, False)
    _GUICtrlComboBox_AddString($hCombo, "This is a test")
    _GUICtrlComboBox_AddDir($hCombo, "", $DDL_DRIVES)
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; 文字列を見つける
    MsgBox(4160, "Information", "Find String: " & _GUICtrlComboBox_FindString($hCombo, "this"))
   
    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main