Function Reference

_GUICtrlComboBox_SetEditSel

コンボボックスのエディットコントロールの文字を選択します。

#Include <GuiComboBox.au3>
_GUICtrlComboBox_SetEditSel($hWnd, $iStart, $iStop)

 

パラメータ

$hWnd コントロールのハンドル
$iStart 開始位置
$iStop 終了位置

 

返し値

成功: True
失敗: $CBS_DROPDOWNLISTスタイルの設定されているコンボボックスにメッセージが送信された場合、False

 

注意

位置はゼロ始まりです。つまりエディットコントロールの最初の文字が位置ゼロです。
$iStopが-1の場合、開始位置からエディットコントロール内の最後の文字までの全テキストが選択されます。

選択されている最終文字の次の文字が終了位置です。

例えば、エディットコントロールの最初の4文字を選択するには開始位置に0を、終了位置に4を使用してください。

 

関連

_GUICtrlComboBox_GetEditSel, _GUICtrlComboBox_ReplaceEditSel

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIComboBox.au3>
#include <GuiConstantsEx.au3>

Opt('MustDeclareVars', 1)

$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Global $iMemo

_Main()

Func _Main()
    Local $aSel, $hCombo

    ; GUIを作成
    GUICreate("ComboBox Set Edit Sel", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; ファイルを追加
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; アイテムを選択
    _GUICtrlComboBox_SetCurSel($hCombo, 2)
   
    ; エディットの選択値を設定
    _GUICtrlComboBox_SetEditSel($hCombo, 0, 4)
   
    ; エディットの選択値を取得
    $aSel = _GUICtrlComboBox_GetEditSel($hCombo)
    MemoWrite(StringFormat("Edit Sel: %d - %d", $aSel[0], $aSel[1]))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite