Function Reference

_GUICtrlComboBox_ShowDropDown

コンボボックスのリストボックスの表示/非表示を切り替えます。

#Include <GuiComboBox.au3>
_GUICtrlComboBox_ShowDropDown($hWnd[, $fShow = False])

 

パラメータ

$hWnd コントロールのハンドル
$fShow [オプション]ドロップダウンリストボックスの表示/非表示を指定します:
 True - リストボックスを表示
False - リストボックスを非表示

 

返し値

なし。

 

注意

この関数は$CBS_SIMPLEスタイルで作成されたコンボボックスには動作しません。

 

関連

_GUICtrlComboBox_GetDroppedState, _GUICtrlComboBoxEx_GetDroppedState

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIComboBox.au3>
#include <GuiConstantsEx.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Global $iMemo

_Main()

Func _Main()
    Local $hCombo

    ; GUIを作成
    GUICreate("ComboBox Show Drop Down", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; ファイルを追加
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; ドロップ状態を取得
    MemoWrite("Dropped Down State......: " & _GUICtrlComboBox_GetDroppedState($hCombo))
   
    Sleep(500)
   
    ; ドロップダウンを表示
    _GUICtrlComboBox_ShowDropDown($hCombo, True)

    Sleep(500)

    ; ドロップ状態を取得
    MemoWrite("Dropped Down State......: " & _GUICtrlComboBox_GetDroppedState($hCombo))

    Sleep(500)

    ; ドロップダウンを非表示
    _GUICtrlComboBox_ShowDropDown($hCombo)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite