IPアドレスコントロールにアドレスを設定します。
#Include <GuiIPAddress.au3>
_GUICtrlIpAddress_SetArray($hWnd, $aAddress)
パラメータ
| $hWnd | コントロールのハンドル |
| $aAddress | 次のフォーマットの配列: [0] - 1つ目のアドレスフィールド [1] - 2つ目のアドレスフィールド [2] - 3つ目のアドレスフィールド [3] - 4つ目のアドレスフィールド |
返し値
なし。
注意
なし。
関連
_GUICtrlIpAddress_GetArray
例
#include <GuiConstantsEx.au3>
#include <GuiIPAddress.au3>
Opt("MustDeclareVars", 1)
$Debug_IP = False ; IPAddress関数に渡されるClassNameを調べる。Trueを設定すると動作確認のために他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $hgui, $aIP[4] = [24, 168, 2, 128], $hIPAddress
$hgui = GUICreate("IP address control Set (Array) Example", 400, 300)
$hIPAddress = _GUICtrlIpAddress_Create ($hgui, 2, 4, 125, 20)
$iMemo = GUICtrlCreateEdit("", 2, 28, 396, 270, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
_GUICtrlIpAddress_SetArray ($hIPAddress, $aIP)
$aIP = _GUICtrlIpAddress_GetArray ($hIPAddress)
MemoWrite("Field 1 .....: " & $aIP[0])
MemoWrite("Field 2 .....: " & $aIP[1])
MemoWrite("Field 3 .....: " & $aIP[2])
MemoWrite("Field 4 .....: " & $aIP[3])
; ユーザーがGUIを閉じるまで待機
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite