テキスト内に指定されたテキストを含むアイテムを検索します。
#Include <GuiListView.au3>
_GUICtrlListView_FindInText($hWnd, $sText[, $iStart = -1[, $fWrapOK = True[, $fReverse = False]]])
パラメータ
| $hWnd | コントロールのハンドル |
| $sText | 検索テキスト |
| $iStart | [オプション]検索開始位置のアイテムのゼロ始まりのインデックス。-1の場合は先頭から検索します。 指定されたアイテム自体は検索対象に含まれません。 |
| $fWrapOK | [オプション]Trueの場合、一致するものがみつからなかった際に1番目のアイテムから検索が継続実行されます。 |
| $fReverse | [オプション]Trueの場合、検索は$iStart-1からゼロまでおこなわれます。$fWrapOK = Trueの場合、検索は継続実行されます。 |
返し値
| 成功: | アイテムのゼロ始まりのインデックス |
| 失敗: | -1 |
注意
検索では大文字小文字は区別されません。
関連
_GUICtrlListView_FindText
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
Opt('MustDeclareVars', 1)
$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $iI, $hListView
GUICreate("ListView Find In Text", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()
; 列を追加
_GUICtrlListView_InsertColumn($hListView, 0, "Items", 100)
; アイテムを追加
_GUICtrlListView_BeginUpdate($hListView)
For $iI = 1 To 49
_GUICtrlListView_AddItem($hListView, "Item " & $iI)
Next
_GUICtrlListView_AddItem($hListView, "Target item")
For $iI = 51 To 100
_GUICtrlListView_AddItem($hListView, "Item " & $iI)
Next
_GUICtrlListView_EndUpdate($hListView)
; ターゲットアイテムを検索
$iI = _GUICtrlListView_FindInText($hListView, "tArGeT")
MsgBox(4160, "Information", "Target Item Index: " & $iI)
_GUICtrlListView_EnsureVisible($hListView, $iI)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main