拡張スタイルを設定します。
#Include <GuiListView.au3>
_GUICtrlListView_SetExtendedListViewStyle($hWnd, $iExStyle[, $iExMask = 0])
パラメータ
| $hWnd | コントロールのハンドル |
| $iExStyle | コントロールの拡張スタイル: $LVS_EX_BORDERSELECT - アイテムが選択された際にアイテムの枠の色が変わります。 $LVS_EX_CHECKBOXES - リストビューコントロールのアイテムのチェックボックスを有効にします。 $LVS_EX_DOUBLEBUFFER - ちらつきを抑えるためにダブルバッファで描画をおこないます。 $LVS_EX_FLATSB - リストビューの平らなスクロールバーを有効にします。 $LVS_EX_FULLROWSELECT - アイテムが選択された際にアイテムとその全てのサブアイテムをハイライトします。 $LVS_EX_GRIDLINES - アイテムとサブアイテムの周りにグリッド線を表示します。 $LVS_EX_HEADERDRAGDROP - ドラッグ&ドロップによる列の順序変更を有効にします。 $LVS_EX_INFOTIP - ツールチップ表示前に$LVN_GETINFOTIP通知メッセージが送信されます。 $LVS_EX_LABELTIP - 設定されていない場合、ラージアイコンモードでのみ部分的に非表示のラベルの展開をおこないます。 $LVS_EX_MULTIWORKAREAS - 1つ以上の作業領域が定義されるまでコントロールはアイコンの自動整列をおこないません。 $LVS_EX_ONECLICKACTIVATE - ユーザーがアイテムをクリックした際にコントロールは$LVN_ITEMACTIVATEメッセージを送信します。 $LVS_EX_REGIONAL - アイテムのアイコンとテキストのみを含むコントロール領域を設定します。 $LVS_EX_SIMPLESELECT - アイコン表示でコントロールの状態画像を右上に移動します。 $LVS_EX_SUBITEMIMAGES - サブアイテムへの画像表示を許可します。 $LVS_EX_TRACKSELECT - コントロールでのホットトラック選択を有効にします。 $LVS_EX_TWOCLICKACTIVATE - ユーザーがアイテムをダブルクリックした際にコントロールは$LVN_ITEMACTIVATEメッセージを送信します。 $LVS_EX_UNDERLINECOLD - アクティブ化されたホットでないアイテムのテキストに下線を表示します。 $LVS_EX_UNDERLINEHOT - アクティブ化されたホットアイテムのテキストに下線を表示します。 |
| $iExMask | [オプション]
$iExStyleのどのスタイルが変更されるかを指定します。 このパラメータは拡張スタイルの組み合わせです。 $iExMask内の拡張スタイルのみ変更され、他のスタイルは維持されます。 このパラメータがゼロの場合、$iExStyle内の全てのスタイルが変更されます。 |
返し値
以前の拡張スタイルを返します。
注意
なし。
関連
_GUICtrlListView_GetExtendedListViewStyle
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
Opt('MustDeclareVars', 1)
$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $hImage, $hListView
; GUIを作成
GUICreate("ListView Set Extended Style", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
GUISetState()
; 画像をロード
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($hListView, $hImage, 1)
; 列を追加
_GUICtrlListView_InsertColumn($hListView, 0, "Column 1", 100)
_GUICtrlListView_InsertColumn($hListView, 1, "Column 2", 100)
_GUICtrlListView_InsertColumn($hListView, 2, "Column 3", 100)
; アイテムを追加
_GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
_GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1, 1)
_GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2, 2)
_GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
_GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1, 2)
_GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main