画像リストをコントロールに割り当てます。
#Include <GuiListView.au3>
_GUICtrlListView_SetImageList($hWnd, $hHandle[, $iType = 0])
パラメータ
| $hWnd | コントロールのハンドル |
| $hHandle | 割り当てる画像リストのハンドル |
| $iType | [オプション]画像リストの種類: 0 - ラージアイコンの画像リスト 1 - スモールアイコンの画像リスト 2 - 状態画像の画像リスト |
返し値
| 成功: | 以前の画像リストのハンドル |
| 失敗: | 0 |
注意
$LVS_SHAREIMAGELISTSスタイルを設定していない場合、現在の画像リストはコントロールが破棄される際に破棄されます。
関連
_GUICtrlListView_GetImageList
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
Opt('MustDeclareVars', 1)
$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $hImage, $hListView
GUICreate("ListView Set Image List", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()
; 画像をロード
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($hListView, $hImage, 1)
; 列を追加
_GUICtrlListView_AddColumn($hListView, "Column 1", 100)
_GUICtrlListView_AddColumn($hListView, "Column 2", 100)
_GUICtrlListView_AddColumn($hListView, "Column 3", 100)
; アイテムを追加
_GUICtrlListView_AddItem($hListView, "Item 1", 0)
_GUICtrlListView_AddItem($hListView, "Item 2", 1)
_GUICtrlListView_AddItem($hListView, "Item 3", 2)
; 画像リストハンドルを取得
MsgBox(4160, "Information", "Image List Handle: 0x" & Hex(_GUICtrlListView_GetImageList($hListView, 1)))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main