チェック状態を設定します。
#Include <GuiListView.au3>
_GUICtrlListView_SetItemChecked($hWnd, $iIndex[, $fCheck = True])
パラメータ
| $hWnd | コントロールのハンドル |
| $iIndex | アイテムのゼロ始まりのインデックス。-1の場合は全てのアイテムが指定されます。 |
| $fCheck | [オプション]チェック状態として設定される値: True - チェック False - チェック解除 |
返し値
| 成功: | True |
| 失敗: | False |
注意
$LVS_EX_CHECKBOXES拡張スタイルのコントロールのみに使用できます。
関連
_GUICtrlListView_GetItemChecked
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
Opt('MustDeclareVars', 1)
$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $exStyles = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES), $hListView
GUICreate("ListView Set Item Checked State", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
_GUICtrlListView_SetExtendedListViewStyle($hListView, $exStyles)
GUISetState()
; 列を追加
_GUICtrlListView_AddColumn($hListView, "Column 1", 100)
_GUICtrlListView_AddColumn($hListView, "Column 2", 100)
_GUICtrlListView_AddColumn($hListView, "Column 3", 100)
; アイテムを追加
_GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
_GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1)
_GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2)
_GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
_GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1)
_GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)
; アイテム2をチェック
_GUICtrlListView_SetItemChecked($hListView, 1)
MsgBox(4160, "Information", "Item 2 Checked: " & _GUICtrlListView_GetItemChecked($hListView, 1))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main