アイテムをコントロール内の指定された位置に移動します。
#Include <GuiListView.au3>
_GUICtrlListView_SetItemPosition($hWnd, $iIndex, $iCX, $iCY)
パラメータ
| $hWnd | コントロールのハンドル |
| $iIndex | アイテムのゼロ始まりのインデックス |
| $iCX | ビュー座標でのアイテム左上隅の新しいX座標 |
| $iCY | ビュー座標でのアイテム左上隅の新しいY座標 |
返し値
| 成功: | True |
| 失敗: | False |
注意
コントロールに$LVS_AUTOARRANGEスタイルが設定されていた場合、コントロール内のアイテムはアイテムの座標が設定された後に整列されます。
関連
_GUICtrlListView_GetItemPosition, _GUICtrlListView_Arrange, _GUICtrlListView_SetItemPosition32
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
Opt('MustDeclareVars', 1)
$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $aPos, $hListView
GUICreate("ListView Set Item Position", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()
; 列を追加
_GUICtrlListView_AddColumn($hListView, "Items", 100)
; アイテムを追加
_GUICtrlListView_BeginUpdate($hListView)
For $iI = 1 To 10
_GUICtrlListView_AddItem($hListView, "Item " & $iI)
Next
_GUICtrlListView_EndUpdate($hListView)
; アイコン表示を設定
_GUICtrlListView_SetView($hListView, 3)
MsgBox(4160, "Information", "Moving item 2")
_GUICtrlListView_SetItemPosition($hListView, 1, 100, 100)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main