指定されたメニューアイテムのチェックマーク属性の状態を選択/非選択に設定します。
#Include <GuiMenu.au3>
_GUICtrlMenu_CheckMenuItem($hMenu, $iItem[, $fCheck = True[, $fByPos = True]])
パラメータ
| $hMenu | メニューのハンドル |
| $iItem | チェックするメニューアイテムの識別子または位置 |
| $fCheck | [オプション]Trueの場合はチェックマークを設定し、Falseの場合はそれを解除します |
| $fByPos | [オプション]メニュー識別子フラグ: True - $iItemはゼロ始まりのアイテム位置です False - $iItemはメニューアイテムの識別子です |
返し値
| 成功: | メニューアイテムの以前の状態($MF_CHECKEDまたは$MF_UNCHECKEDのどちらか) |
| 失敗: | -1 |
注意
メニューバー内のアイテムにはチェックマークを設定できません。
関連
_GUICtrlMenu_CheckRadioItem
こちらも参照
MSDNライブラリでCheckMenuItemを検索して下さい。
例
#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout
; GUIを作成
$hGUI = GUICreate("Menu", 400, 300)
; ファイルメニューを作成
$hFile = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hFile, 0, "&New", $idNew)
_GUICtrlMenu_InsertMenuItem ($hFile, 1, "&Open", $idOpen)
_GUICtrlMenu_InsertMenuItem ($hFile, 2, "&Save", $idSave)
_GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
_GUICtrlMenu_InsertMenuItem ($hFile, 4, "E&xit", $idExit)
; 編集メニューを作成
$hEdit = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hEdit, 0, "&Cut", $idCut)
_GUICtrlMenu_InsertMenuItem ($hEdit, 1, "C&opy", $idCopy)
_GUICtrlMenu_InsertMenuItem ($hEdit, 2, "&Paste", $idPaste)
; ヘルプメニューを作成
$hHelp = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hHelp, 0, "&About", $idAbout)
; メインメニューを作成
$hMain = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hMain, 0, "&File", 0, $hFile)
_GUICtrlMenu_InsertMenuItem ($hMain, 1, "&Edit", 0, $hEdit)
_GUICtrlMenu_InsertMenuItem ($hMain, 2, "&Help", 0, $hHelp)
; ウィンドウにメニューを設定
_GUICtrlMenu_SetMenu ($hGUI, $hMain)
GUISetState()
; メニューアイテム"アバウト"をチェック
_GUICtrlMenu_CheckMenuItem ($hHelp, 0)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main